perl/AGWMsg.pm

   1 #
   2 # This class is the internal subclass that deals with AGW Engine connections
   3 #
   4 # The complication here is that there only one 'real' (and from the node's point
   5 # of view, invisible) IP connection. This connection then has multiplexed
   6 # connections passed down it, a la BPQ native host ports (but not as nicely).
   7 #
   8 # It is a shame that the author has chosen an inherently dangerous binary format
   9 # which is non-framed and has the potential for getting out of sync and not
  10 # being able to recover. Relying on length fields is recipe for disaster (esp.
  11 # for him!). DoS attacks are a wonderful thing....
  12 #
  13 # Also making the user handle the distinction between a level 2 and 4 connection
  14 # and especially Digis, in the way that he has, is a bit of a cop out! If I can
  15 # be arsed to do anything other than straight ax25 connects then it will only
  16 # because I have the 'power of perl' available that avoids me getting
  17 # terminally bored sorting out other people's sloppyness.
  18 #
  19 # $Id$
  20 #
  21 # Copyright (c) 2001 - Dirk Koopman G1TLH
  22 #
  23
  24 package AGWMsg;
  25
  26 use strict;
  27 use IO::Socket;
  28 use Msg;
  29 use AGWConnect;
  30 use DXDebug;
  31
  32 use vars qw(@ISA $sock @outqueue $send_offset $inmsg $rproc $noports $lastytime
  33                         $lasthtime $ypolltime $hpolltime %circuit);
  34
  35 @ISA = qw(Msg ExtMsg);
  36 $sock = undef;
  37 @outqueue = ();
  38 $send_offset = 0;
  39 $inmsg = '';
  40 $rproc = undef;
  41 $noports = 0;
  42 $lastytime = $lasthtime = time;
  43 $ypolltime = 10 unless defined $ypolltime;
  44 $hpolltime = 300 unless defined $hpolltime;
  45 %circuit = ();
  46
  47 use vars qw($VERSION $BRANCH);
  48 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  49 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
  50 $main::build += $VERSION;
  51 $main::branch += $BRANCH;
  52
  53 sub init
  54 {
  55         return unless $enable;
  56         $rproc = shift;
  57
  58         finish();
  59         dbg("AGW initialising and connecting to $addr/$port ...");
  60         $sock = IO::Socket::INET->new(PeerAddr => $addr, PeerPort => $port, Proto=>'tcp', Timeout=>15);
  61         unless ($sock) {
  62                 dbg("Cannot connect to AGW Engine at $addr/$port $!");
  63                 return;
  64         }
  65         Msg::blocking($sock, 0);
  66         Msg::set_event_handler($sock, read=>\&_rcv, error=>\&_error);
  67
  68         # send a P frame for the login if required
  69         if ($login) {
  70                 my $data = pack "a255 a255", $login, $passwd;
  71                 _sendf('P', undef, undef, undef, undef, $data);
  72         }
  73
  74         # send:
  75         # R frame for the release number
  76         # G frame to ask for ports
  77         # X frame to say who we are
  78         # optional m frame to enable monitoring
  79         _sendf('R');
  80         _sendf('G');
  81         _sendf('X', $main::mycall);
  82         _sendf('m') if $monitor;
  83 }
  84
  85 my $finishing = 0;
  86
  87 sub finish
  88 {
  89         return if $finishing;
  90         if ($sock) {
  91                 $finishing = 1;
  92                 dbg("AGW ending...");
  93                 for (values %circuit) {
  94                         &{$_->{eproc}}() if $_->{eproc};
  95                         $_->disconnect;
  96                 }
  97                 # say we are going
  98                 _sendf('m') if $monitor;
  99                 _sendf('x', $main::mycall);
 100                 Msg->sleep(2);
 101                 Msg::set_event_handler($sock, read=>undef, write=>undef, error=>undef);
 102                 $sock->close;
 103         }
 104 }
 105
 106 sub active
 107 {
 108         return $sock;
 109 }
 110
 111 sub _sendf
 112 {
 113         my $sort = shift || confess "need a valid AGW command letter";
 114         my $from = shift || '';
 115         my $to   = shift || '';
 116         my $port = shift || 0;
 117         my $pid  = shift || 0;
 118         my $data = shift || '';
 119         my $len  = 0;
 120
 121         $len = length $data;
 122         if ($sort eq 'y' || $sort eq 'H') {
 123                 dbg("AGW sendf: $sort '${from}'->'${to}' port: $port pid: $pid \"$data\"") if isdbg('agwpoll');
 124         } elsif ($sort eq 'D') {
 125                 if (isdbg('agw')) {
 126                         my $d = $data;
 127                         $d =~ s/\cM$//;
 128                         dbg("AGW sendf: $sort '${from}'->'${to}' port: $port pid: $pid \"$d\"") if isdbg('agw');
 129                 }
 130         } else {
 131                 dbg("AGW sendf: $sort '${from}'->'${to}' port: $port pid: $pid \"$data\"") if isdbg('agw');
 132         }
 133         push @outqueue, pack('C x3 a1 x1 C x1 a10 a10 V x4 a*', $port, $sort, $pid, $from, $to, $len, $data);
 134         Msg::set_event_handler($sock, write=>\&_send);
 135 }
 136
 137 sub _send
 138 {
 139     return unless $sock;
 140
 141     # If $flush is set, set the socket to blocking, and send all
 142     # messages in the queue - return only if there's an error
 143     # If $flush is 0 (deferred mode) make the socket non-blocking, and
 144     # return to the event loop only after every message, or if it
 145     # is likely to block in the middle of a message.
 146
 147     my $offset = $send_offset;
 148
 149     while (@outqueue) {
 150         my $msg            = $outqueue[0];
 151                 my $mlth           = length($msg);
 152         my $bytes_to_write = $mlth - $offset;
 153         my $bytes_written  = 0;
 154                 confess("Negative Length! msg: '$msg' lth: $mlth offset: $offset") if $bytes_to_write < 0;
 155         while ($bytes_to_write > 0) {
 156             $bytes_written = syswrite ($sock, $msg,
 157                                        $bytes_to_write, $offset);
 158             if (!defined($bytes_written)) {
 159                 if (Msg::_err_will_block($!)) {
 160                     # Should happen only in deferred mode. Record how
 161                     # much we have already sent.
 162                     $send_offset = $offset;
 163                     # Event handler should already be set, so we will
 164                     # be called back eventually, and will resume sending
 165                     return 1;
 166                 } else {    # Uh, oh
 167                                         _error();
 168                     return 0; # fail. Message remains in queue ..
 169                 }
 170             }
 171                         if (isdbg('raw')) {
 172                                 dbgdump('raw', "AGW send $bytes_written: ", $msg);
 173                         }
 174             $offset         += $bytes_written;
 175             $bytes_to_write -= $bytes_written;
 176         }
 177         $send_offset = $offset = 0;
 178         shift @outqueue;
 179         last;  # Go back to select and wait
 180                        # for it to fire again.
 181     }
 182
 183     # Call me back if queue has not been drained.
 184     if (@outqueue) {
 185         Msg::set_event_handler ($sock, write => \&_send);
 186     } else {
 187         Msg::set_event_handler ($sock, write => undef);
 188     }
 189     1;  # Success
 190 }
 191
 192 sub _rcv {                     # Complement to _send
 193     return unless $sock;
 194     my ($msg, $offset, $bytes_read);
 195
 196         $bytes_read = sysread ($sock, $msg, 1024, 0);
 197         if (defined ($bytes_read)) {
 198                 if ($bytes_read > 0) {
 199                         $inmsg .= $msg;
 200                         if (isdbg('raw')) {
 201                                 dbgdump('raw', "AGW read $bytes_read: ", $msg);
 202                         }
 203                 }
 204         } else {
 205                 if (Msg::_err_will_block($!)) {
 206                         return;
 207                 } else {
 208                         $bytes_read = 0;
 209                 }
 210     }
 211
 212 FINISH:
 213     if (defined $bytes_read && $bytes_read == 0) {
 214                 finish();
 215     } else {
 216                 _decode() if length $inmsg >= 36;
 217         }
 218 }
 219
 220 sub _error
 221 {
 222         dbg("error on AGW connection $addr/$port $!");
 223         Msg::set_event_handler($sock, read=>undef, write=>undef, error=>undef);
 224         $sock = undef;
 225         for (%circuit) {
 226                 &{$_->{eproc}}() if $_->{eproc};
 227                 $_->disconnect;
 228         }
 229 }
 230
 231 sub _decode
 232 {
 233         return unless $sock;
 234
 235         # we have at least 36 bytes of data (ugh!)
 236         while (length $inmsg >= 36) {
 237                 my ($port, $sort, $pid, $from, $to, $len) = unpack('C x3 a1 x1 C x1 Z10 Z10 V x4', $inmsg);
 238                 my $data;
 239
 240                 # do a sanity check on the length
 241                 if ($len > 2000) {
 242                         dbg("AGW: invalid length $len > 2000 received ($sort $port $pid '$from'->'$to')");
 243                         finish();
 244                         return;
 245                 }
 246                 if ($len == 0){
 247                         if (length $inmsg > 36) {
 248                                 $inmsg = substr($inmsg, 36);
 249                         } else {
 250                                 $inmsg = '';
 251                         }
 252                 } elsif (length $inmsg > $len + 36) {
 253                         $data = substr($inmsg, 36, $len);
 254                         $inmsg = substr($inmsg, $len + 36);
 255                 } elsif (length $inmsg == $len + 36) {
 256                         $data = substr($inmsg, 36);
 257                         $inmsg = '';
 258                 } else {
 259                         #
 260                         # we don't have enough data or something
 261                         # or we have screwed up
 262                         #
 263                         return;
 264                 }
 265
 266                 $data = '' unless defined $data;
 267                 if ($sort eq 'D') {
 268                         my $d = unpack "Z*", $data;
 269                         $d =~ s/\cM\cJ?$//;
 270                         $d =~ s/^\cJ//;
 271                         dbg("AGW Data In port: $port pid: $pid '$from'->'$to' length: $len \"$d\"") if isdbg('agw');
 272                         my $conn = _find($from eq $main::mycall ? $to : $from);
 273                         if ($conn) {
 274                                 if ($conn->{state} eq 'WC') {
 275                                         if (exists $conn->{cmd}) {
 276                                                 if (@{$conn->{cmd}}) {
 277                                                         dbg($d) if isdbg('connect');
 278                                                         $conn->_docmd($d);
 279                                                 }
 280                                         }
 281                                         if ($conn->{state} eq 'WC' && exists $conn->{cmd} && @{$conn->{cmd}} == 0) {
 282                                                 $conn->to_connected($conn->{call}, 'O', $conn->{csort});
 283                                         }
 284                                 } else {
 285                                         my @lines = split /\cM\cJ?/, $d;
 286                                         push @lines, $d unless @lines;
 287                                         for (@lines) {
 288                                                 &{$conn->{rproc}}($conn, "I$conn->{call}|$_");
 289                                         }
 290                                 }
 291                         } else {
 292                                 dbg("AGW error Unsolicited Data!");
 293                         }
 294                 } elsif ($sort eq 'I' || $sort eq 'S' || $sort eq 'U' || $sort eq 'M' || $sort eq 'T') {
 295                         my $d = unpack "Z*", $data;
 296                         $d =~ s/^\cJ//;
 297                         $d =~ s/\cM\cJ?$//;
 298                         my @lines = split /\cM\cJ?/, $d;
 299
 300                         for (@lines) {
 301 #                               s/([\x00-\x1f\x7f-\xff])/sprintf("%%%02X", ord($1))/eg;
 302                                 dbg("AGW Monitor port: $port \"$_\"") if isdbg('agw');
 303                         }
 304                 } elsif ($sort eq 'C') {
 305                         my $d = unpack "Z*", $data;
 306                         $d =~ s/\cM\cJ?$//;
 307                         dbg("AGW Connect port: $port pid: $pid '$from'->'$to' \"$d\"") if isdbg('agw');
 308                         my $call = $from eq $main::mycall ? $to : $from;
 309                         my $conn = _find($call);
 310                         if ($conn) {
 311                                 if ($conn->{state} eq 'WC') {
 312                                         if (exists $conn->{cmd} && @{$conn->{cmd}}) {
 313                                                 $conn->_docmd($d);
 314                                                 if ($conn->{state} eq 'WC' && exists $conn->{cmd} &&  @{$conn->{cmd}} == 0) {
 315                                                         $conn->to_connected($conn->{call}, 'O', $conn->{csort});
 316                                                 }
 317                                         }
 318                                 }
 319                         } else {
 320                                 $conn = AGWMsg->new($rproc);
 321                                 $conn->{agwpid} = $pid;
 322                                 $conn->{agwport} = $port;
 323                                 $conn->{lineend} = "\cM";
 324                                 $conn->{incoming} = 1;
 325                                 $conn->{agwcall} = $call;
 326                                 $circuit{$call} = $conn;
 327                                 if ($call =~ /^(\w+)-(\d\d?)$/) {
 328                                         my $c = $1;
 329                                         my $s = $2;
 330                                         $s = 15 - $s;
 331                                         if ($s <= 8 && $s > 0) {
 332                                                 $call = "${c}-${s}";
 333                                         } else {
 334                                                 $call = $c;
 335                                         }
 336                                 }
 337                                 $conn->to_connected($call, 'A', $conn->{csort} = 'ax25');
 338                         }
 339                 } elsif ($sort eq 'd') {
 340                         my $d = unpack "Z*", $data;
 341                         $d =~ s/\cM\cJ?$//;
 342                         dbg("AGW '$from'->'$to' port: $port Disconnected ($d)") if isdbg('agw');
 343                         my $conn = _find($from eq $main::mycall ? $to : $from);
 344                         if ($conn) {
 345                                 &{$conn->{eproc}}() if $conn->{eproc};
 346                                 $conn->in_disconnect;
 347                         }
 348                 } elsif ($sort eq 'y') {
 349                         my ($frames) = unpack "V", $data;
 350                         dbg("AGW Frames Outstanding on port $port = $frames") if isdbg('agwpollans');
 351                         my $conn = _find($from);
 352                         $conn->{oframes} = $frames if $conn;
 353                 } elsif ($sort eq 'Y') {
 354                         my ($frames) = unpack "V", $data;
 355                         dbg("AGW Frames Outstanding on circuit '$from'->'$to' = $frames") if isdbg('agw');
 356                         my $conn = _find($from eq $main::mycall ? $to : $from);
 357                         $conn->{oframes} = $frames if $conn;
 358                 } elsif ($sort eq 'H') {
 359                         unless ($from =~ /^\s+$/) {
 360                                 my $d = unpack "Z*", $data;
 361                                 $d =~ s/\cM\cJ?$//;
 362                                 dbg("AGW Heard port: $port \"$d\"") if isdbg('agw');
 363                         }
 364                 } elsif ($sort eq 'X') {
 365                         my ($r) = unpack "C", $data;
 366                         $r = $r ? "Successful" : "Failed";
 367                         dbg("AGW Register $from $r");
 368                         finish() unless $r;
 369                 } elsif ($sort eq 'R') {
 370                         my ($major, $minor) = unpack "v x2 v x2", $data;
 371                         dbg("AGW Version $major.$minor") if isdbg('agw');
 372                 } elsif ($sort eq 'G') {
 373                         my @ports = split /;/, $data;
 374                         $noports = shift @ports || '0';
 375                         dbg("AGW $noports Ports available") if isdbg('agw');
 376                         pop @ports while @ports > $noports;
 377                         for (@ports) {
 378                                 next unless $_;
 379                                 dbg("AGW Port: $_") if isdbg('agw');
 380                         }
 381                         for (my $i = 0; $i < $noports; $i++) {
 382                                 _sendf('y', undef, undef, $i);
 383                                 _sendf('g', undef, undef, $i);
 384                         }
 385                 } else {
 386                         my $d = unpack "Z*", $data;
 387                         dbg("AGW decode $sort port: $port pid: $pid '$from'->'$to' length: $len \"$d\"") if isdbg('agw');
 388                 }
 389         }
 390 }
 391
 392 sub _find
 393 {
 394         my $call = shift;
 395         return $circuit{$call};
 396 }
 397
 398 sub connect
 399 {
 400         my ($conn, $line) = @_;
 401
 402         my ($port, $call) = split /\s+/, $line;
 403         $conn->{agwpid} = ord "\xF0";
 404         $conn->{agwport} = $port - 1;
 405         $conn->{lineend} = "\cM";
 406         $conn->{incoming} = 0;
 407         $conn->{csort} = 'ax25';
 408         $conn->{agwcall} = uc $call;
 409         $circuit{$conn->{agwcall}} = $conn;
 410
 411         _sendf('C', $main::mycall, $conn->{agwcall}, $conn->{agwport}, $conn->{agwpid});
 412         $conn->{state} = 'WC';
 413
 414         return 1;
 415 }
 416
 417 sub in_disconnect
 418 {
 419         my $conn = shift;
 420         delete $circuit{$conn->{agwcall}};
 421         $conn->SUPER::disconnect;
 422 }
 423
 424 sub disconnect
 425 {
 426         my $conn = shift;
 427         delete $circuit{$conn->{agwcall}};
 428         if ($conn->{incoming}) {
 429                 _sendf('d', $conn->{agwcall}, $main::mycall, $conn->{agwport}, $conn->{agwpid});
 430         } else {
 431                 _sendf('d', $main::mycall, $conn->{agwcall}, $conn->{agwport}, $conn->{agwpid});
 432         }
 433         $conn->SUPER::disconnect;
 434 }
 435
 436 sub enqueue
 437 {
 438         my ($conn, $msg) = @_;
 439         if ($msg =~ /^D/) {
 440                 $msg =~ s/^[-\w]+\|//;
 441 #               _sendf('Y', $main::mycall, $conn->{call}, $conn->{agwport}, $conn->{agwpid});
 442                 _sendf('D', $main::mycall, $conn->{agwcall}, $conn->{agwport}, $conn->{agwpid}, $msg . $conn->{lineend});
 443                 my $len = length($msg) + 1;
 444                 dbg("AGW Data Out port: $conn->{agwport} pid: $conn->{agwpid} '$main::mycall'->'$conn->{agwcall}' length: $len \"$msg\"") if isdbg('agw');
 445         }
 446 }
 447
 448 sub process
 449 {
 450         return unless $sock;
 451         if ($ypolltime && $main::systime - $lastytime >= $ypolltime) {
 452                 for (my $i = 0; $i < $noports; $i++) {
 453                         _sendf('y', undef, undef, $i );
 454                 }
 455                 $lastytime = $main::systime;
 456         }
 457         if ($hpolltime && $main::systime - $lasthtime >= $hpolltime) {
 458                 for (my $i = 0; $i < $noports; $i++) {
 459                         _sendf('H', undef, undef, $i );
 460                 }
 461                 $lasthtime = $main::systime;
 462         }
 463 }
 464
 465 1;
 466