perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   gtk => '5,Using GTK,yesno',
 105                   senddbg => '8,Sending Debug,yesno',
 106                   width => '0,Column Width',
 107                   disconnecting => '9,Disconnecting,yesno',
 108                   ann_talk => '0,Suppress Talk Anns,yesno',
 109                   metric => '1,Route metric',
 110                   badcount => '1,Bad Word Count',
 111                   edit => '7,Edit Function',
 112                   registered => '9,Registered?,yesno',
 113                   prompt => '0,Required Prompt',
 114                   version => '1,Node Version',
 115                   build => '1,Node Build',
 116                   verified => '9,Verified?,yesno',
 117                   newroute => '1,New Style Routing,yesno',
 118                   ve7cc => '0,VE7CC program special,yesno',
 119                   lastmsgpoll => '0,Last Msg Poll,atime',
 120                   inscript => '9,In a script,yesno',
 121                   handle_xml => '9,Handles XML,yesno',
 122                   do_pc9x => '9,Handles PC9x,yesno',
 123                   inqueue => '9,Input Queue,parray',
 124                  );
 125
 126
 127 use vars qw($VERSION $BRANCH);
 128 ($VERSION, $BRANCH) = dxver(q$Revision$);
 129
 130 # object destruction
 131 sub DESTROY
 132 {
 133         my $self = shift;
 134         for (keys %$self) {
 135                 if (ref($self->{$_})) {
 136                         delete $self->{$_};
 137                 }
 138         }
 139         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 140         $count--;
 141 }
 142
 143 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 144 sub alloc
 145 {
 146         my ($pkg, $call, $conn, $user) = @_;
 147         my $self = {};
 148
 149         die "trying to create a duplicate channel for $call" if $channels{$call};
 150         $self->{call} = $call;
 151         $self->{priv} = 0;
 152         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 153         if (defined $user) {
 154                 $self->{user} = $user;
 155                 $self->{lang} = $user->lang;
 156                 $user->new_group unless $user->group;
 157                 $user->new_buddies unless $user->buddies;
 158                 $self->{group} = $user->group;
 159                 $self->{sort} = $user->sort;
 160         }
 161         $self->{startt} = $self->{t} = time;
 162         $self->{state} = 0;
 163         $self->{oldstate} = 0;
 164         $self->{lang} = $main::lang if !$self->{lang};
 165         $self->{func} = "";
 166
 167         # add in all the dxcc, itu, zone info
 168         my @dxcc = Prefix::extract($call);
 169         if (@dxcc > 0) {
 170                 $self->{dxcc} = $dxcc[1]->dxcc;
 171                 $self->{itu} = $dxcc[1]->itu;
 172                 $self->{cq} = $dxcc[1]->cq;
 173         }
 174         $self->{inqueue} = [];
 175
 176         $count++;
 177         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 178         bless $self, $pkg;
 179         return $channels{$call} = $self;
 180 }
 181
 182 # rebless this channel as something else
 183 sub rebless
 184 {
 185         my $self = shift;
 186         my $class = shift;
 187         return $channels{$self->{call}} = bless $self, $class;
 188 }
 189
 190 sub rec
 191 {
 192         my ($self, $msg) = @_;
 193
 194         # queue the message and the channel object for later processing
 195         if (defined $msg) {
 196                 push @{$self->{inqueue}}, $msg;
 197         }
 198 }
 199
 200 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 201 sub get
 202 {
 203         my $call = shift;
 204         return $channels{$call};
 205 }
 206
 207 # obtain all the channel objects
 208 sub get_all
 209 {
 210         return values(%channels);
 211 }
 212
 213 #
 214 # gimme all the ak1a nodes
 215 #
 216 sub get_all_nodes
 217 {
 218         my $ref;
 219         my @out;
 220         foreach $ref (values %channels) {
 221                 push @out, $ref if $ref->is_node;
 222         }
 223         return @out;
 224 }
 225
 226 # return a list of all users
 227 sub get_all_users
 228 {
 229         my $ref;
 230         my @out;
 231         foreach $ref (values %channels) {
 232                 push @out, $ref if $ref->is_user;
 233         }
 234         return @out;
 235 }
 236
 237 # return a list of all user callsigns
 238 sub get_all_user_calls
 239 {
 240         my $ref;
 241         my @out;
 242         foreach $ref (values %channels) {
 243                 push @out, $ref->{call} if $ref->is_user;
 244         }
 245         return @out;
 246 }
 247
 248 # obtain a channel object by searching for its connection reference
 249 sub get_by_cnum
 250 {
 251         my ($pkg, $conn) = @_;
 252         my $self;
 253
 254         foreach $self (values(%channels)) {
 255                 return $self if ($self->{conn} == $conn);
 256         }
 257         return undef;
 258 }
 259
 260 # get rid of a channel object [$obj->del()]
 261 sub del
 262 {
 263         my $self = shift;
 264
 265         $self->{group} = undef;         # belt and braces
 266         delete $channels{$self->{call}};
 267 }
 268
 269 # is it a bbs
 270 sub is_bbs
 271 {
 272         my $self = shift;
 273         return $self->{'sort'} eq 'B';
 274 }
 275
 276 sub is_node
 277 {
 278         my $self = shift;
 279         return $self->{'sort'} =~ /[ACRSXW]/;
 280 }
 281 # is it an ak1a node ?
 282 sub is_ak1a
 283 {
 284         my $self = shift;
 285         return $self->{'sort'} eq 'A';
 286 }
 287
 288 # is it a user?
 289 sub is_user
 290 {
 291         my $self = shift;
 292         return $self->{'sort'} eq 'U';
 293 }
 294
 295 # is it a clx node
 296 sub is_clx
 297 {
 298         my $self = shift;
 299         return $self->{'sort'} eq 'C';
 300 }
 301
 302 # it is Aranea
 303 sub is_aranea
 304 {
 305         my $self = shift;
 306         return $self->{'sort'} eq 'W';
 307 }
 308
 309 # is it a spider node
 310 sub is_spider
 311 {
 312         my $self = shift;
 313         return $self->{'sort'} eq 'S';
 314 }
 315
 316 # is it a DXNet node
 317 sub is_dxnet
 318 {
 319         my $self = shift;
 320         return $self->{'sort'} eq 'X';
 321 }
 322
 323 # is it a ar-cluster node
 324 sub is_arcluster
 325 {
 326         my $self = shift;
 327         return $self->{'sort'} eq 'R';
 328 }
 329
 330 # for perl 5.004's benefit
 331 sub sort
 332 {
 333         my $self = shift;
 334         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 335 }
 336
 337 # find out whether we are prepared to believe this callsign on this interface
 338 sub is_believed
 339 {
 340         my $self = shift;
 341         my $call = shift;
 342
 343         return grep $call eq $_, $self->user->believe;
 344 }
 345
 346 # handle out going messages, immediately without waiting for the select to drop
 347 # this could, in theory, block
 348 sub send_now
 349 {
 350         my $self = shift;
 351         my $conn = $self->{conn};
 352         return unless $conn;
 353         my $sort = shift;
 354         my $call = $self->{call};
 355
 356         for (@_) {
 357 #               chomp;
 358         my @lines = split /\n/;
 359                 for (@lines) {
 360                         $conn->send_now("$sort$call|$_");
 361                         # debug log it, but not if it is a log message
 362                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 363                 }
 364         }
 365         $self->{t} = time;
 366 }
 367
 368 #
 369 # send later with letter (more control)
 370 #
 371
 372 sub send_later
 373 {
 374         my $self = shift;
 375         my $conn = $self->{conn};
 376         return unless $conn;
 377         my $sort = shift;
 378         my $call = $self->{call};
 379
 380         for (@_) {
 381 #               chomp;
 382         my @lines = split /\n/;
 383                 for (@lines) {
 384                         $conn->send_later("$sort$call|$_");
 385                         # debug log it, but not if it is a log message
 386                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 387                 }
 388         }
 389         $self->{t} = time;
 390 }
 391
 392 #
 393 # the normal output routine
 394 #
 395 sub send                                                # this is always later and always data
 396 {
 397         my $self = shift;
 398         my $conn = $self->{conn};
 399         return unless $conn;
 400         my $call = $self->{call};
 401
 402         foreach my $l (@_) {
 403                 for (ref $l ? @$l : $l) {
 404                         my @lines = split /\n/;
 405                         for (@lines) {
 406                                 $conn->send_later("D$call|$_");
 407                                 dbg("-> D $call $_") if isdbg('chan');
 408                         }
 409                 }
 410         }
 411         $self->{t} = $main::systime;
 412 }
 413
 414 # send a file (always later)
 415 sub send_file
 416 {
 417         my ($self, $fn) = @_;
 418         my $call = $self->{call};
 419         my $conn = $self->{conn};
 420         my @buf;
 421
 422         open(F, $fn) or die "can't open $fn for sending file ($!)";
 423         @buf = <F>;
 424         close(F);
 425         $self->send(@buf);
 426 }
 427
 428 # this will implement language independence (in time)
 429 sub msg
 430 {
 431         my $self = shift;
 432         return DXM::msg($self->{lang}, @_);
 433 }
 434
 435 # stick a broadcast on the delayed queue (but only up to 20 items)
 436 sub delay
 437 {
 438         my $self = shift;
 439         my $s = shift;
 440
 441         $self->{delayed} = [] unless $self->{delayed};
 442         push @{$self->{delayed}}, $s;
 443         if (@{$self->{delayed}} >= 20) {
 444                 shift @{$self->{delayed}};   # lose oldest one
 445         }
 446 }
 447
 448 # change the state of the channel - lots of scope for debugging here :-)
 449 sub state
 450 {
 451         my $self = shift;
 452         if (@_) {
 453                 $self->{oldstate} = $self->{state};
 454                 $self->{state} = shift;
 455                 $self->{func} = '' unless defined $self->{func};
 456                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 457
 458                 # if there is any queued up broadcasts then splurge them out here
 459                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 460                         $self->send (@{$self->{delayed}});
 461                         delete $self->{delayed};
 462                 }
 463         }
 464         return $self->{state};
 465 }
 466
 467 # disconnect this channel
 468 sub disconnect
 469 {
 470         my $self = shift;
 471         my $user = $self->{user};
 472
 473         $user->close() if defined $user;
 474         $self->{conn}->disconnect if $self->{conn};
 475         $self->del();
 476 }
 477
 478 #
 479 # just close all the socket connections down without any fiddling about, cleaning, being
 480 # nice to other processes and otherwise telling them what is going on.
 481 #
 482 # This is for the benefit of forked processes to prepare for starting new programs, they
 483 # don't want or need all this baggage.
 484 #
 485
 486 sub closeall
 487 {
 488         my $ref;
 489         foreach $ref (values %channels) {
 490                 $ref->{conn}->disconnect() if $ref->{conn};
 491         }
 492 }
 493
 494 #
 495 # Tell all the users that we have come in or out (if they want to know)
 496 #
 497 sub tell_login
 498 {
 499         my ($self, $m, $call) = @_;
 500
 501         $call ||= $self->{call};
 502
 503         # send info to all logged in thingies
 504         my @dxchan = get_all_users();
 505         my $dxchan;
 506         foreach $dxchan (@dxchan) {
 507                 next if $dxchan == $self;
 508                 next if $dxchan->{call} eq $main::mycall;
 509                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 510         }
 511 }
 512
 513 #
 514 # Tell all the users if a buddy is logged or out
 515 #
 516 sub tell_buddies
 517 {
 518         my ($self, $m, $call, $node) = @_;
 519
 520         $call ||= $self->{call};
 521         $call =~ s/-\d+$//;
 522         $m .= 'n' if $node;
 523
 524         # send info to all logged in thingies
 525         my @dxchan = get_all_users();
 526         my $dxchan;
 527         foreach $dxchan (@dxchan) {
 528                 next if $dxchan == $self;
 529                 next if $dxchan->{call} eq $main::mycall;
 530                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 531         }
 532 }
 533
 534 # various access routines
 535
 536 #
 537 # return a list of valid elements
 538 #
 539
 540 sub fields
 541 {
 542         return keys(%valid);
 543 }
 544
 545 #
 546 # return a prompt for a field
 547 #
 548
 549 sub field_prompt
 550 {
 551         my ($self, $ele) = @_;
 552         return $valid{$ele};
 553 }
 554
 555 # take a standard input message and decode it into its standard parts
 556 sub decode_input
 557 {
 558         my $dxchan = shift;
 559         my $data = shift;
 560         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 561
 562         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 563
 564         # the above regexp must work
 565         unless (defined $sort && defined $call && defined $line) {
 566 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 567                 dbg("DUFF Line on $chcall: $data");
 568                 return ();
 569         }
 570
 571         if(ref($dxchan) && $call ne $chcall) {
 572                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 573                 return();
 574         }
 575
 576         return ($sort, $call, $line);
 577 }
 578
 579 sub rspfcheck
 580 {
 581         my ($self, $flag, $node, $user) = @_;
 582         my $nref = Route::Node::get($node);
 583         my $dxchan = $nref->dxchan if $nref;
 584         if ($nref && $dxchan) {
 585             if ($dxchan == $self) {
 586                         return 1 unless $user;
 587                         return 1 if $user eq $node;
 588                         my @users = $nref->users;
 589                         return 1 if @users == 0 || grep $user eq $_, @users;
 590                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 591                 } else {
 592                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 593                 }
 594         } else {
 595                 return 1 if $flag;
 596                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 597         }
 598         return 0;
 599 }
 600
 601 # broadcast a message to all clusters taking into account isolation
 602 # [except those mentioned after buffer]
 603 sub broadcast_nodes
 604 {
 605         my $s = shift;                          # the line to be rebroadcast
 606         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 607         my @dxchan = get_all_nodes();
 608         my $dxchan;
 609
 610         # send it if it isn't the except list and isn't isolated and still has a hop count
 611         foreach $dxchan (@dxchan) {
 612                 next if grep $dxchan == $_, @except;
 613                 next if $dxchan == $main::me;
 614
 615                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 616
 617                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 618         }
 619 }
 620
 621 # broadcast a message to all clusters ignoring isolation
 622 # [except those mentioned after buffer]
 623 sub broadcast_all_nodes
 624 {
 625         my $s = shift;                          # the line to be rebroadcast
 626         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 627         my @dxchan = get_all_nodes();
 628         my $dxchan;
 629
 630         # send it if it isn't the except list and isn't isolated and still has a hop count
 631         foreach $dxchan (@dxchan) {
 632                 next if grep $dxchan == $_, @except;
 633                 next if $dxchan == $main::me;
 634
 635                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 636                 $dxchan->send($routeit);
 637         }
 638 }
 639
 640 # broadcast to all users
 641 # storing the spot or whatever until it is in a state to receive it
 642 sub broadcast_users
 643 {
 644         my $s = shift;                          # the line to be rebroadcast
 645         my $sort = shift;           # the type of transmission
 646         my $fref = shift;           # a reference to an object to filter on
 647         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 648         my @dxchan = get_all_users();
 649         my $dxchan;
 650         my @out;
 651
 652         foreach $dxchan (@dxchan) {
 653                 next if grep $dxchan == $_, @except;
 654                 push @out, $dxchan;
 655         }
 656         broadcast_list($s, $sort, $fref, @out);
 657 }
 658
 659
 660 # broadcast to a list of users
 661 sub broadcast_list
 662 {
 663         my $s = shift;
 664         my $sort = shift;
 665         my $fref = shift;
 666         my $dxchan;
 667
 668         foreach $dxchan (@_) {
 669                 my $filter = 1;
 670                 next if $dxchan == $main::me;
 671
 672                 if ($sort eq 'dx') {
 673                     next unless $dxchan->{dx};
 674                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 675                         next unless $filter;
 676                 }
 677                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 678                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 679                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 680                 next if $sort eq 'wx' && !$dxchan->{wx};
 681
 682                 $s =~ s/\a//og unless $dxchan->{beep};
 683
 684                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 685                         $dxchan->send($s);
 686                 } else {
 687                         $dxchan->delay($s);
 688                 }
 689         }
 690 }
 691
 692 sub process
 693 {
 694         foreach my $dxchan (get_all()) {
 695
 696                 while (my $data = shift @{$dxchan->{inqueue}}) {
 697                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 698                         next unless defined $sort;
 699
 700                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 701                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 702                         if ($dxchan->{disconnecting}) {
 703                                 dbg('In disconnection, ignored');
 704                                 next;
 705                         }
 706
 707                         # handle A records
 708                         my $user = $dxchan->user;
 709                         if ($sort eq 'A' || $sort eq 'O') {
 710                                 $dxchan->start($line, $sort);
 711                         } elsif ($sort eq 'I') {
 712                                 die "\$user not defined for $call" if !defined $user;
 713
 714                                 # normal input
 715                                 $dxchan->normal($line);
 716                         } elsif ($sort eq 'Z') {
 717                                 $dxchan->disconnect;
 718                         } elsif ($sort eq 'D') {
 719                                 ;                               # ignored (an echo)
 720                         } elsif ($sort eq 'G') {
 721                                 $dxchan->enhanced($line);
 722                         } else {
 723                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 724                         }
 725                 }
 726         }
 727 }
 728
 729 sub handle_xml
 730 {
 731         my $self = shift;
 732         my $r = 0;
 733
 734         if (DXXml::available()) {
 735                 $r = $self->{handle_xml} || 0;
 736         } else {
 737                 delete $self->{handle_xml} if exists $self->{handle_xml};
 738         }
 739         return $r;
 740 }
 741
 742 #no strict;
 743 sub AUTOLOAD
 744 {
 745         no strict;
 746         my $name = $AUTOLOAD;
 747         return if $name =~ /::DESTROY$/;
 748         $name =~ s/^.*:://o;
 749
 750         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 751
 752         # this clever line of code creates a subroutine which takes over from autoload
 753         # from OO Perl - Conway
 754         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 755         goto &$AUTOLOAD;
 756 }
 757
 758
 759 1;
 760 __END__;