perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35
  36 use strict;
  37 use vars qw(%channels %valid @ISA $count);
  38
  39 %channels = ();
  40 $count = 0;
  41
  42 %valid = (
  43                   call => '0,Callsign',
  44                   conn => '9,Msg Conn ref',
  45                   user => '9,DXUser ref',
  46                   startt => '0,Start Time,atime',
  47                   t => '9,Time,atime',
  48                   pc50_t => '5,Last PC50 Time,atime',
  49                   priv => '9,Privilege',
  50                   state => '0,Current State',
  51                   oldstate => '5,Last State',
  52                   list => '9,Dep Chan List',
  53                   name => '0,User Name',
  54                   consort => '5,Connection Type',
  55                   'sort' => '5,Type of Channel',
  56                   wwv => '0,Want WWV,yesno',
  57                   wcy => '0,Want WCY,yesno',
  58                   wx => '0,Want WX,yesno',
  59                   talk => '0,Want Talk,yesno',
  60                   ann => '0,Want Announce,yesno',
  61                   here => '0,Here?,yesno',
  62                   conf => '0,In Conference?,yesno',
  63                   dx => '0,DX Spots,yesno',
  64                   redirect => '0,Redirect messages to',
  65                   lang => '0,Language',
  66                   func => '5,Function',
  67                   loc => '9,Local Vars', # used by func to store local variables in
  68                   beep => '0,Want Beeps,yesno',
  69                   lastread => '5,Last Msg Read',
  70                   outbound => '5,outbound?,yesno',
  71                   remotecmd => '9,doing rcmd,yesno',
  72                   pagelth => '0,Page Length',
  73                   pagedata => '9,Page Data Store',
  74                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  75                   isolate => '5,Isolate network,yesno',
  76                   delayed => '5,Delayed messages,parray',
  77                   annfilter => '5,Announce Filter',
  78                   wwvfilter => '5,WWV Filter',
  79                   wcyfilter => '5,WCY Filter',
  80                   spotsfilter => '5,Spot Filter',
  81                   routefilter => '5,route Filter',
  82                   inannfilter => '5,Input Ann Filter',
  83                   inwwvfilter => '5,Input WWV Filter',
  84                   inwcyfilter => '5,Input WCY Filter',
  85                   inspotsfilter => '5,Input Spot Filter',
  86                   inroutefilter => '5,Input Route Filter',
  87                   passwd => '9,Passwd List,parray',
  88                   pingint => '5,Ping Interval ',
  89                   nopings => '5,Ping Obs Count',
  90                   lastping => '5,Ping last sent,atime',
  91                   pingtime => '5,Ping totaltime,parray',
  92                   pingave => '0,Ping ave time',
  93                   logininfo => '9,Login info req,yesno',
  94                   talklist => '0,Talk List,parray',
  95                   cluster => '5,Cluster data',
  96                   isbasic => '9,Internal Connection',
  97                   errors => '9,Errors',
  98                   route => '9,Route Data',
  99                   dxcc => '0,Country Code',
 100                   itu => '0,ITU Zone',
 101                   cq => '0,CQ Zone',
 102                   enhanced => '5,Enhanced Client,yesno',
 103                   senddbg => '8,Sending Debug,yesno',
 104                  );
 105
 106 use vars qw($VERSION $BRANCH);
 107 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 108 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/ ) || 0;
 109 $main::build += $VERSION;
 110 $main::branch += $BRANCH;
 111
 112 # object destruction
 113 sub DESTROY
 114 {
 115         my $self = shift;
 116         for (keys %$self) {
 117                 if (ref($self->{$_})) {
 118                         delete $self->{$_};
 119                 }
 120         }
 121         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 122         $count--;
 123 }
 124
 125 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 126 sub alloc
 127 {
 128         my ($pkg, $call, $conn, $user) = @_;
 129         my $self = {};
 130
 131         die "trying to create a duplicate channel for $call" if $channels{$call};
 132         $self->{call} = $call;
 133         $self->{priv} = 0;
 134         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 135         if (defined $user) {
 136                 $self->{user} = $user;
 137                 $self->{lang} = $user->lang;
 138                 $user->new_group() if !$user->group;
 139                 $self->{group} = $user->group;
 140                 $self->{sort} = $user->sort;
 141         }
 142         $self->{startt} = $self->{t} = time;
 143         $self->{state} = 0;
 144         $self->{oldstate} = 0;
 145         $self->{lang} = $main::lang if !$self->{lang};
 146         $self->{func} = "";
 147
 148         # add in all the dxcc, itu, zone info
 149         my @dxcc = Prefix::extract($call);
 150         if (@dxcc > 0) {
 151                 $self->{dxcc} = $dxcc[1]->dxcc;
 152                 $self->{itu} = $dxcc[1]->itu;
 153                 $self->{cq} = $dxcc[1]->cq;
 154         }
 155
 156         $count++;
 157         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 158         bless $self, $pkg;
 159         return $channels{$call} = $self;
 160 }
 161
 162 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 163 sub get
 164 {
 165         my ($pkg, $call) = @_;
 166         return $channels{$call};
 167 }
 168
 169 # obtain all the channel objects
 170 sub get_all
 171 {
 172         my ($pkg) = @_;
 173         return values(%channels);
 174 }
 175
 176 #
 177 # gimme all the ak1a nodes
 178 #
 179 sub get_all_nodes
 180 {
 181         my $ref;
 182         my @out;
 183         foreach $ref (values %channels) {
 184                 push @out, $ref if $ref->is_node;
 185         }
 186         return @out;
 187 }
 188
 189 # return a list of all users
 190 sub get_all_users
 191 {
 192         my $ref;
 193         my @out;
 194         foreach $ref (values %channels) {
 195                 push @out, $ref if $ref->is_user;
 196         }
 197         return @out;
 198 }
 199
 200 # return a list of all user callsigns
 201 sub get_all_user_calls
 202 {
 203         my $ref;
 204         my @out;
 205         foreach $ref (values %channels) {
 206                 push @out, $ref->{call} if $ref->is_user;
 207         }
 208         return @out;
 209 }
 210
 211 # obtain a channel object by searching for its connection reference
 212 sub get_by_cnum
 213 {
 214         my ($pkg, $conn) = @_;
 215         my $self;
 216
 217         foreach $self (values(%channels)) {
 218                 return $self if ($self->{conn} == $conn);
 219         }
 220         return undef;
 221 }
 222
 223 # get rid of a channel object [$obj->del()]
 224 sub del
 225 {
 226         my $self = shift;
 227
 228         $self->{group} = undef;         # belt and braces
 229         delete $channels{$self->{call}};
 230 }
 231
 232 # is it a bbs
 233 sub is_bbs
 234 {
 235         my $self = shift;
 236         return $self->{'sort'} eq 'B';
 237 }
 238
 239 sub is_node
 240 {
 241         my $self = shift;
 242         return $self->{'sort'} =~ /[ACRSX]/;
 243 }
 244 # is it an ak1a node ?
 245 sub is_ak1a
 246 {
 247         my $self = shift;
 248         return $self->{'sort'} eq 'A';
 249 }
 250
 251 # is it a user?
 252 sub is_user
 253 {
 254         my $self = shift;
 255         return $self->{'sort'} eq 'U';
 256 }
 257
 258 # is it a clx node
 259 sub is_clx
 260 {
 261         my $self = shift;
 262         return $self->{'sort'} eq 'C';
 263 }
 264
 265 # is it a spider node
 266 sub is_spider
 267 {
 268         my $self = shift;
 269         return $self->{'sort'} eq 'S';
 270 }
 271
 272 # is it a DXNet node
 273 sub is_dxnet
 274 {
 275         my $self = shift;
 276         return $self->{'sort'} eq 'X';
 277 }
 278
 279 # is it a ar-cluster node
 280 sub is_arcluster
 281 {
 282         my $self = shift;
 283         return $self->{'sort'} eq 'R';
 284 }
 285
 286 # for perl 5.004's benefit
 287 sub sort
 288 {
 289         my $self = shift;
 290         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 291 }
 292
 293 # handle out going messages, immediately without waiting for the select to drop
 294 # this could, in theory, block
 295 sub send_now
 296 {
 297         my $self = shift;
 298         my $conn = $self->{conn};
 299         return unless $conn;
 300         my $sort = shift;
 301         my $call = $self->{call};
 302
 303         for (@_) {
 304 #               chomp;
 305         my @lines = split /\n/;
 306                 for (@lines) {
 307                         $conn->send_now("$sort$call|$_");
 308                         dbg("-> $sort $call $_") if isdbg('chan');
 309                 }
 310         }
 311         $self->{t} = time;
 312 }
 313
 314 #
 315 # send later with letter (more control)
 316 #
 317
 318 sub send_later
 319 {
 320         my $self = shift;
 321         my $conn = $self->{conn};
 322         return unless $conn;
 323         my $sort = shift;
 324         my $call = $self->{call};
 325
 326         for (@_) {
 327 #               chomp;
 328         my @lines = split /\n/;
 329                 for (@lines) {
 330                         $conn->send_later("$sort$call|$_");
 331                         dbg("-> $sort $call $_") if isdbg('chan');
 332                 }
 333         }
 334         $self->{t} = time;
 335 }
 336
 337 #
 338 # the normal output routine
 339 #
 340 sub send                                                # this is always later and always data
 341 {
 342         my $self = shift;
 343         my $conn = $self->{conn};
 344         return unless $conn;
 345         my $call = $self->{call};
 346
 347         for (@_) {
 348 #               chomp;
 349         my @lines = split /\n/;
 350                 for (@lines) {
 351                         $conn->send_later("D$call|$_");
 352                         dbg("-> D $call $_") if isdbg('chan');
 353                 }
 354         }
 355         $self->{t} = time;
 356 }
 357
 358 # send a file (always later)
 359 sub send_file
 360 {
 361         my ($self, $fn) = @_;
 362         my $call = $self->{call};
 363         my $conn = $self->{conn};
 364         my @buf;
 365
 366         open(F, $fn) or die "can't open $fn for sending file ($!)";
 367         @buf = <F>;
 368         close(F);
 369         $self->send(@buf);
 370 }
 371
 372 # this will implement language independence (in time)
 373 sub msg
 374 {
 375         my $self = shift;
 376         return DXM::msg($self->{lang}, @_);
 377 }
 378
 379 # stick a broadcast on the delayed queue (but only up to 20 items)
 380 sub delay
 381 {
 382         my $self = shift;
 383         my $s = shift;
 384
 385         $self->{delayed} = [] unless $self->{delayed};
 386         push @{$self->{delayed}}, $s;
 387         if (@{$self->{delayed}} >= 20) {
 388                 shift @{$self->{delayed}};   # lose oldest one
 389         }
 390 }
 391
 392 # change the state of the channel - lots of scope for debugging here :-)
 393 sub state
 394 {
 395         my $self = shift;
 396         if (@_) {
 397                 $self->{oldstate} = $self->{state};
 398                 $self->{state} = shift;
 399                 $self->{func} = '' unless defined $self->{func};
 400                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 401
 402                 # if there is any queued up broadcasts then splurge them out here
 403                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 404                         $self->send (@{$self->{delayed}});
 405                         delete $self->{delayed};
 406                 }
 407         }
 408         return $self->{state};
 409 }
 410
 411 # disconnect this channel
 412 sub disconnect
 413 {
 414         my $self = shift;
 415         my $user = $self->{user};
 416
 417         $user->close() if defined $user;
 418         $self->{conn}->disconnect;
 419         $self->del();
 420 }
 421
 422 #
 423 # just close all the socket connections down without any fiddling about, cleaning, being
 424 # nice to other processes and otherwise telling them what is going on.
 425 #
 426 # This is for the benefit of forked processes to prepare for starting new programs, they
 427 # don't want or need all this baggage.
 428 #
 429
 430 sub closeall
 431 {
 432         my $ref;
 433         foreach $ref (values %channels) {
 434                 $ref->{conn}->disconnect() if $ref->{conn};
 435         }
 436 }
 437
 438 #
 439 # Tell all the users that we have come in or out (if they want to know)
 440 #
 441 sub tell_login
 442 {
 443         my ($self, $m) = @_;
 444
 445         # send info to all logged in thingies
 446         my @dxchan = get_all_users();
 447         my $dxchan;
 448         foreach $dxchan (@dxchan) {
 449                 next if $dxchan == $self;
 450                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 451         }
 452 }
 453
 454 # various access routines
 455
 456 #
 457 # return a list of valid elements
 458 #
 459
 460 sub fields
 461 {
 462         return keys(%valid);
 463 }
 464
 465 #
 466 # return a prompt for a field
 467 #
 468
 469 sub field_prompt
 470 {
 471         my ($self, $ele) = @_;
 472         return $valid{$ele};
 473 }
 474
 475 # take a standard input message and decode it into its standard parts
 476 sub decode_input
 477 {
 478         my $dxchan = shift;
 479         my $data = shift;
 480         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 481
 482         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 483
 484         # the above regexp must work
 485         unless (defined $sort && defined $call && defined $line) {
 486 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 487                 dbg("DUFF Line on $chcall: $data") if isdbg('err');
 488                 return ();
 489         }
 490
 491         if(ref($dxchan) && $call ne $chcall) {
 492                 dbg("DUFF Line come in for $call on wrong channel $chcall") if isdbg('err');
 493                 return();
 494         }
 495
 496         return ($sort, $call, $line);
 497 }
 498
 499 no strict;
 500 sub AUTOLOAD
 501 {
 502         my $self = shift;
 503         my $name = $AUTOLOAD;
 504         return if $name =~ /::DESTROY$/;
 505         $name =~ s/.*:://o;
 506
 507         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 508
 509         # this clever line of code creates a subroutine which takes over from autoload
 510         # from OO Perl - Conway
 511         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}} ;
 512     @_ ? $self->{$name} = shift : $self->{$name} ;
 513 }
 514
 515
 516 1;
 517 __END__;