perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Filter;
  33 use Carp;
  34
  35 use strict;
  36 use vars qw(%channels %valid);
  37
  38 %channels = ();
  39
  40 %valid = (
  41                   call => '0,Callsign',
  42                   conn => '9,Msg Conn ref',
  43                   user => '9,DXUser ref',
  44                   startt => '0,Start Time,atime',
  45                   t => '9,Time,atime',
  46                   pc50_t => '5,Last PC50 Time,atime',
  47                   priv => '9,Privilege',
  48                   state => '0,Current State',
  49                   oldstate => '5,Last State',
  50                   list => '9,Dep Chan List',
  51                   name => '0,User Name',
  52                   consort => '5,Connection Type',
  53                   'sort' => '5,Type of Channel',
  54                   wwv => '0,Want WWV,yesno',
  55                   wx => '0,Want WX,yesno',
  56                   talk => '0,Want Talk,yesno',
  57                   ann => '0,Want Announce,yesno',
  58                   here => '0,Here?,yesno',
  59                   confmode => '0,In Conference?,yesno',
  60                   dx => '0,DX Spots,yesno',
  61                   redirect => '0,Redirect messages to',
  62                   lang => '0,Language',
  63                   func => '5,Function',
  64                   loc => '9,Local Vars', # used by func to store local variables in
  65                   beep => '0,Want Beeps,yesno',
  66                   lastread => '5,Last Msg Read',
  67                   outbound => '5,outbound?,yesno',
  68                   remotecmd => '9,doing rcmd,yesno',
  69                   pagelth => '0,Page Length',
  70                   pagedata => '9,Page Data Store',
  71                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  72                   isolate => '5,Isolate network,yesno',
  73                   delayed => '5,Delayed messages,parray',
  74                   annfilter => '5,Announce Filter',
  75                   wwvfilter => '5,WWV Filter',
  76                   spotfilter => '5,Spot Filter',
  77                   inannfilter => '5,Input Ann Filter',
  78                   inwwvfilter => '5,Input WWV Filter',
  79                   inspotfilter => '5,Input Spot Filter',
  80                   passwd => '9,Passwd List,parray',
  81                  );
  82
  83 # object destruction
  84 sub DESTROY
  85 {
  86         my $self = shift;
  87         undef $self->{user};
  88         undef $self->{conn};
  89         undef $self->{loc};
  90         undef $self->{pagedata};
  91         undef $self->{group};
  92         undef $self->{delayed};
  93         undef $self->{annfilter};
  94         undef $self->{wwvfilter};
  95         undef $self->{spotfilter};
  96         undef $self->{inannfilter};
  97         undef $self->{inwwvfilter};
  98         undef $self->{inspotfilter};
  99         undef $self->{passwd};
 100 }
 101
 102 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 103 sub alloc
 104 {
 105         my ($pkg, $call, $conn, $user) = @_;
 106         my $self = {};
 107
 108         die "trying to create a duplicate channel for $call" if $channels{$call};
 109         $self->{call} = $call;
 110         $self->{priv} = 0;
 111         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 112         if (defined $user) {
 113                 $self->{user} = $user;
 114                 $self->{lang} = $user->lang;
 115                 $user->new_group() if !$user->group;
 116                 $self->{group} = $user->group;
 117         }
 118         $self->{startt} = $self->{t} = time;
 119         $self->{state} = 0;
 120         $self->{oldstate} = 0;
 121         $self->{lang} = $main::lang if !$self->{lang};
 122         $self->{func} = "";
 123
 124         # get the filters
 125         $self->{spotfilter} = Filter::read_in('spots', $call, 0);
 126         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0);
 127         $self->{annfilter} = Filter::read_in('ann', $call, 0);
 128
 129         bless $self, $pkg;
 130         return $channels{$call} = $self;
 131 }
 132
 133 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 134 sub get
 135 {
 136         my ($pkg, $call) = @_;
 137         return $channels{$call};
 138 }
 139
 140 # obtain all the channel objects
 141 sub get_all
 142 {
 143         my ($pkg) = @_;
 144         return values(%channels);
 145 }
 146
 147 # obtain a channel object by searching for its connection reference
 148 sub get_by_cnum
 149 {
 150         my ($pkg, $conn) = @_;
 151         my $self;
 152
 153         foreach $self (values(%channels)) {
 154                 return $self if ($self->{conn} == $conn);
 155         }
 156         return undef;
 157 }
 158
 159 # get rid of a channel object [$obj->del()]
 160 sub del
 161 {
 162         my $self = shift;
 163
 164         $self->{group} = undef;         # belt and braces
 165         delete $channels{$self->{call}};
 166 }
 167
 168 # is it an ak1a cluster ?
 169 sub is_ak1a
 170 {
 171         my $self = shift;
 172         return $self->{'sort'} eq 'A';
 173 }
 174
 175 # is it a user?
 176 sub is_user
 177 {
 178         my $self = shift;
 179         return $self->{'sort'} eq 'U';
 180 }
 181
 182 # is it a connect type
 183 sub is_connect
 184 {
 185         my $self = shift;
 186         return $self->{'sort'} eq 'C';
 187 }
 188
 189 # handle out going messages, immediately without waiting for the select to drop
 190 # this could, in theory, block
 191 sub send_now
 192 {
 193         my $self = shift;
 194         my $conn = $self->{conn};
 195         my $sort = shift;
 196         my $call = $self->{call};
 197
 198         for (@_) {
 199                 chomp;
 200                 $conn->send_now("$sort$call|$_") if $conn;
 201                 dbg('chan', "-> $sort $call $_") if $conn;
 202         }
 203         $self->{t} = time;
 204 }
 205
 206 #
 207 # the normal output routine
 208 #
 209 sub send                                                # this is always later and always data
 210 {
 211         my $self = shift;
 212         my $conn = $self->{conn};
 213         my $call = $self->{call};
 214
 215         for (@_) {
 216                 chomp;
 217                 $conn->send_later("D$call|$_") if $conn;
 218                 dbg('chan', "-> D $call $_") if $conn;
 219         }
 220         $self->{t} = time;
 221 }
 222
 223 # send a file (always later)
 224 sub send_file
 225 {
 226         my ($self, $fn) = @_;
 227         my $call = $self->{call};
 228         my $conn = $self->{conn};
 229         my @buf;
 230
 231         open(F, $fn) or die "can't open $fn for sending file ($!)";
 232         @buf = <F>;
 233         close(F);
 234         $self->send(@buf);
 235 }
 236
 237 # this will implement language independence (in time)
 238 sub msg
 239 {
 240         my $self = shift;
 241         return DXM::msg($self->{lang}, @_);
 242 }
 243
 244 # stick a broadcast on the delayed queue (but only up to 20 items)
 245 sub delay
 246 {
 247         my $self = shift;
 248         my $s = shift;
 249
 250         $self->{delayed} = [] unless $self->{delayed};
 251         push @{$self->{delayed}}, $s;
 252         if (@{$self->{delayed}} >= 20) {
 253                 shift @{$self->{delayed}};   # lose oldest one
 254         }
 255 }
 256
 257 # change the state of the channel - lots of scope for debugging here :-)
 258 sub state
 259 {
 260         my $self = shift;
 261         if (@_) {
 262                 $self->{oldstate} = $self->{state};
 263                 $self->{state} = shift;
 264                 $self->{func} = '' unless defined $self->{func};
 265                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 266
 267                 # if there is any queued up broadcasts then splurge them out here
 268                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 269                         $self->send (@{$self->{delayed}});
 270                         delete $self->{delayed};
 271                 }
 272         }
 273         return $self->{state};
 274 }
 275
 276 # disconnect this channel
 277 sub disconnect
 278 {
 279         my $self = shift;
 280         my $user = $self->{user};
 281         my $conn = $self->{conn};
 282         my $call = $self->{call};
 283
 284         $self->finish();
 285         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 286         $user->close() if defined $user;
 287         $conn->disconnect() if $conn;
 288         $self->del();
 289 }
 290
 291 #
 292 # just close all the socket connections down without any fiddling about, cleaning, being
 293 # nice to other processes and otherwise telling them what is going on.
 294 #
 295 # This is for the benefit of forked processes to prepare for starting new programs, they
 296 # don't want or need all this baggage.
 297 #
 298
 299 sub closeall
 300 {
 301         my $ref;
 302         foreach $ref (values %channels) {
 303                 $ref->{conn}->disconnect() if $ref->{conn};
 304         }
 305 }
 306
 307 # various access routines
 308
 309 #
 310 # return a list of valid elements
 311 #
 312
 313 sub fields
 314 {
 315         return keys(%valid);
 316 }
 317
 318 #
 319 # return a prompt for a field
 320 #
 321
 322 sub field_prompt
 323 {
 324         my ($self, $ele) = @_;
 325         return $valid{$ele};
 326 }
 327
 328 no strict;
 329 sub AUTOLOAD
 330 {
 331         my $self = shift;
 332         my $name = $AUTOLOAD;
 333         return if $name =~ /::DESTROY$/;
 334         $name =~ s/.*:://o;
 335
 336         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 337         @_ ? $self->{$name} = shift : $self->{$name} ;
 338 }
 339
 340 1;
 341 __END__;