perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Filter;
  33 use Carp;
  34
  35 use strict;
  36 use vars qw(%channels %valid);
  37
  38 %channels = ();
  39
  40 %valid = (
  41                   call => '0,Callsign',
  42                   conn => '9,Msg Conn ref',
  43                   user => '9,DXUser ref',
  44                   startt => '0,Start Time,atime',
  45                   t => '9,Time,atime',
  46                   pc50_t => '5,Last PC50 Time,atime',
  47                   priv => '9,Privilege',
  48                   state => '0,Current State',
  49                   oldstate => '5,Last State',
  50                   list => '9,Dep Chan List',
  51                   name => '0,User Name',
  52                   consort => '5,Connection Type',
  53                   'sort' => '5,Type of Channel',
  54                   wwv => '0,Want WWV,yesno',
  55                   wx => '0,Want WX,yesno',
  56                   talk => '0,Want Talk,yesno',
  57                   ann => '0,Want Announce,yesno',
  58                   here => '0,Here?,yesno',
  59                   confmode => '0,In Conference?,yesno',
  60                   dx => '0,DX Spots,yesno',
  61                   redirect => '0,Redirect messages to',
  62                   lang => '0,Language',
  63                   func => '5,Function',
  64                   loc => '9,Local Vars', # used by func to store local variables in
  65                   beep => '0,Want Beeps,yesno',
  66                   lastread => '5,Last Msg Read',
  67                   outbound => '5,outbound?,yesno',
  68                   remotecmd => '9,doing rcmd,yesno',
  69                   pagelth => '0,Page Length',
  70                   pagedata => '9,Page Data Store',
  71                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  72                   isolate => '5,Isolate network,yesno',
  73                   delayed => '5,Delayed messages,parray',
  74                   annfilter => '5,Announce Filter',
  75                   wwvfilter => '5,WWV Filter',
  76                   spotfilter => '5,Spot Filter',
  77                   inannfilter => '5,Input Ann Filter',
  78                   inwwvfilter => '5,Input WWV Filter',
  79                   inspotfilter => '5,Input Spot Filter',
  80                   passwd => '9,Passwd List,parray',
  81                   pingint => '5,Ping Interval ',
  82                   nopings => '5,Ping Obs Count',
  83                   lastping => '5,Ping last sent,atime',
  84                   pingtime => '5,Ping totaltime,parray',
  85                   pingave => '0,Ping ave time',
  86                   logininfo => '9,Login info req,yesno',
  87                  );
  88
  89 # object destruction
  90 sub DESTROY
  91 {
  92         my $self = shift;
  93         undef $self->{user};
  94         undef $self->{conn};
  95         undef $self->{loc};
  96         undef $self->{pagedata};
  97         undef $self->{group};
  98         undef $self->{delayed};
  99         undef $self->{annfilter};
 100         undef $self->{wwvfilter};
 101         undef $self->{spotfilter};
 102         undef $self->{inannfilter};
 103         undef $self->{inwwvfilter};
 104         undef $self->{inspotfilter};
 105         undef $self->{passwd};
 106 }
 107
 108 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 109 sub alloc
 110 {
 111         my ($pkg, $call, $conn, $user) = @_;
 112         my $self = {};
 113
 114         die "trying to create a duplicate channel for $call" if $channels{$call};
 115         $self->{call} = $call;
 116         $self->{priv} = 0;
 117         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 118         if (defined $user) {
 119                 $self->{user} = $user;
 120                 $self->{lang} = $user->lang;
 121                 $user->new_group() if !$user->group;
 122                 $self->{group} = $user->group;
 123         }
 124         $self->{startt} = $self->{t} = time;
 125         $self->{state} = 0;
 126         $self->{oldstate} = 0;
 127         $self->{lang} = $main::lang if !$self->{lang};
 128         $self->{func} = "";
 129
 130         # get the filters
 131         $self->{spotfilter} = Filter::read_in('spots', $call, 0);
 132         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0);
 133         $self->{annfilter} = Filter::read_in('ann', $call, 0);
 134
 135         bless $self, $pkg;
 136         return $channels{$call} = $self;
 137 }
 138
 139 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 140 sub get
 141 {
 142         my ($pkg, $call) = @_;
 143         return $channels{$call};
 144 }
 145
 146 # obtain all the channel objects
 147 sub get_all
 148 {
 149         my ($pkg) = @_;
 150         return values(%channels);
 151 }
 152
 153 #
 154 # gimme all the ak1a nodes
 155 #
 156 sub get_all_ak1a
 157 {
 158         my @list = DXChannel->get_all();
 159         my $ref;
 160         my @out;
 161         foreach $ref (@list) {
 162                 push @out, $ref if $ref->is_ak1a;
 163         }
 164         return @out;
 165 }
 166
 167 # return a list of all users
 168 sub get_all_users
 169 {
 170         my @list = DXChannel->get_all();
 171         my $ref;
 172         my @out;
 173         foreach $ref (@list) {
 174                 push @out, $ref if $ref->is_user;
 175         }
 176         return @out;
 177 }
 178
 179 # return a list of all user callsigns
 180 sub get_all_user_calls
 181 {
 182         my @list = DXChannel->get_all();
 183         my $ref;
 184         my @out;
 185         foreach $ref (@list) {
 186                 push @out, $ref->call if $ref->is_user;
 187         }
 188         return @out;
 189 }
 190
 191 # obtain a channel object by searching for its connection reference
 192 sub get_by_cnum
 193 {
 194         my ($pkg, $conn) = @_;
 195         my $self;
 196
 197         foreach $self (values(%channels)) {
 198                 return $self if ($self->{conn} == $conn);
 199         }
 200         return undef;
 201 }
 202
 203 # get rid of a channel object [$obj->del()]
 204 sub del
 205 {
 206         my $self = shift;
 207
 208         $self->{group} = undef;         # belt and braces
 209         delete $channels{$self->{call}};
 210 }
 211
 212 # is it a bbs
 213 sub is_bbs
 214 {
 215         my $self = shift;
 216         return $self->{'sort'} eq 'B';
 217 }
 218
 219 # is it an ak1a cluster ?
 220 sub is_ak1a
 221 {
 222         my $self = shift;
 223         return $self->{'sort'} eq 'A';
 224 }
 225
 226 # is it a user?
 227 sub is_user
 228 {
 229         my $self = shift;
 230         return $self->{'sort'} eq 'U';
 231 }
 232
 233 # is it a connect type
 234 sub is_connect
 235 {
 236         my $self = shift;
 237         return $self->{'sort'} eq 'C';
 238 }
 239
 240 # for perl 5.004's benefit
 241 sub sort
 242 {
 243         my $self = shift;
 244         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 245 }
 246
 247 # handle out going messages, immediately without waiting for the select to drop
 248 # this could, in theory, block
 249 sub send_now
 250 {
 251         my $self = shift;
 252         my $conn = $self->{conn};
 253         return unless $conn;
 254         my $sort = shift;
 255         my $call = $self->{call};
 256
 257         for (@_) {
 258                 chomp;
 259         my @lines = split /\n/;
 260                 for (@lines) {
 261                         $conn->send_now("$sort$call|$_");
 262                         dbg('chan', "-> $sort $call $_");
 263                 }
 264         }
 265         $self->{t} = time;
 266 }
 267
 268 #
 269 # the normal output routine
 270 #
 271 sub send                                                # this is always later and always data
 272 {
 273         my $self = shift;
 274         my $conn = $self->{conn};
 275         return unless $conn;
 276         my $call = $self->{call};
 277
 278         for (@_) {
 279                 chomp;
 280         my @lines = split /\n/;
 281                 for (@lines) {
 282                         $conn->send_later("D$call|$_");
 283                         dbg('chan', "-> D $call $_");
 284                 }
 285         }
 286         $self->{t} = time;
 287 }
 288
 289 # send a file (always later)
 290 sub send_file
 291 {
 292         my ($self, $fn) = @_;
 293         my $call = $self->{call};
 294         my $conn = $self->{conn};
 295         my @buf;
 296
 297         open(F, $fn) or die "can't open $fn for sending file ($!)";
 298         @buf = <F>;
 299         close(F);
 300         $self->send(@buf);
 301 }
 302
 303 # this will implement language independence (in time)
 304 sub msg
 305 {
 306         my $self = shift;
 307         return DXM::msg($self->{lang}, @_);
 308 }
 309
 310 # stick a broadcast on the delayed queue (but only up to 20 items)
 311 sub delay
 312 {
 313         my $self = shift;
 314         my $s = shift;
 315
 316         $self->{delayed} = [] unless $self->{delayed};
 317         push @{$self->{delayed}}, $s;
 318         if (@{$self->{delayed}} >= 20) {
 319                 shift @{$self->{delayed}};   # lose oldest one
 320         }
 321 }
 322
 323 # change the state of the channel - lots of scope for debugging here :-)
 324 sub state
 325 {
 326         my $self = shift;
 327         if (@_) {
 328                 $self->{oldstate} = $self->{state};
 329                 $self->{state} = shift;
 330                 $self->{func} = '' unless defined $self->{func};
 331                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 332
 333                 # if there is any queued up broadcasts then splurge them out here
 334                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'convers')) {
 335                         $self->send (@{$self->{delayed}});
 336                         delete $self->{delayed};
 337                 }
 338         }
 339         return $self->{state};
 340 }
 341
 342 # disconnect this channel
 343 sub disconnect
 344 {
 345         my $self = shift;
 346         my $user = $self->{user};
 347         my $conn = $self->{conn};
 348         my $call = $self->{call};
 349     my $nopc39 = shift || 0;
 350
 351         $self->finish($nopc39);
 352         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 353         $user->close() if defined $user;
 354         $conn->disconnect() if $conn;
 355         $self->del();
 356 }
 357
 358 #
 359 # just close all the socket connections down without any fiddling about, cleaning, being
 360 # nice to other processes and otherwise telling them what is going on.
 361 #
 362 # This is for the benefit of forked processes to prepare for starting new programs, they
 363 # don't want or need all this baggage.
 364 #
 365
 366 sub closeall
 367 {
 368         my $ref;
 369         foreach $ref (values %channels) {
 370                 $ref->{conn}->disconnect() if $ref->{conn};
 371         }
 372 }
 373
 374 #
 375 # Tell all the users that we have come in or out (if they want to know)
 376 #
 377 sub tell_login
 378 {
 379         my ($self, $m) = @_;
 380
 381         # send info to all logged in thingies
 382         my @dxchan = get_all_users();
 383         my $dxchan;
 384         foreach $dxchan (@dxchan) {
 385                 next if $dxchan == $self;
 386                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 387         }
 388 }
 389
 390 # various access routines
 391
 392 #
 393 # return a list of valid elements
 394 #
 395
 396 sub fields
 397 {
 398         return keys(%valid);
 399 }
 400
 401 #
 402 # return a prompt for a field
 403 #
 404
 405 sub field_prompt
 406 {
 407         my ($self, $ele) = @_;
 408         return $valid{$ele};
 409 }
 410
 411 no strict;
 412 sub AUTOLOAD
 413 {
 414         my $self = shift;
 415         my $name = $AUTOLOAD;
 416         return if $name =~ /::DESTROY$/;
 417         $name =~ s/.*:://o;
 418
 419         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 420         @_ ? $self->{$name} = shift : $self->{$name} ;
 421 }
 422
 423 1;
 424 __END__;