perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Carp;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = ();
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '9,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '9,Connection Type',
  52                   'sort' => '9,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   talk => '0,Want Talk,yesno',
  55                   ann => '0,Want Announce,yesno',
  56                   here => '0,Here?,yesno',
  57                   confmode => '0,In Conference?,yesno',
  58                   dx => '0,DX Spots,yesno',
  59                   redirect => '0,Redirect messages to',
  60                   lang => '0,Language',
  61                   func => '9,Function',
  62                   loc => '9,Local Vars', # used by func to store local variables in
  63                   beep => '0,Want Beeps,yesno',
  64                   lastread => '9,Last Msg Read',
  65                   outbound => '9,outbound?,yesno',
  66                   remotecmd => '9,doing rcmd,yesno',
  67                   pagelth => '0,Page Length',
  68                   pagedata => '9,Page Data Store',
  69                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  70                   isolate => '9,Isolate network,yesno',
  71                  );
  72
  73 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
  74 sub alloc
  75 {
  76         my ($pkg, $call, $conn, $user) = @_;
  77         my $self = {};
  78
  79         die "trying to create a duplicate channel for $call" if $channels{$call};
  80         $self->{call} = $call;
  81         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
  82         $self->{user} = $user if defined $user;
  83         $self->{startt} = $self->{t} = time;
  84         $self->{state} = 0;
  85         $self->{oldstate} = 0;
  86         $self->{lang} = $user->{lang} if defined $user;
  87         $self->{lang} = $main::lang if !$self->{lang};
  88         $user->new_group() if !$user->group;
  89         $self->{group} = $user->group;
  90         $self->{func} = "";
  91         bless $self, $pkg;
  92         return $channels{$call} = $self;
  93 }
  94
  95 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
  96 sub get
  97 {
  98         my ($pkg, $call) = @_;
  99         return $channels{$call};
 100 }
 101
 102 # obtain all the channel objects
 103 sub get_all
 104 {
 105         my ($pkg) = @_;
 106         return values(%channels);
 107 }
 108
 109 # obtain a channel object by searching for its connection reference
 110 sub get_by_cnum
 111 {
 112         my ($pkg, $conn) = @_;
 113         my $self;
 114
 115         foreach $self (values(%channels)) {
 116                 return $self if ($self->{conn} == $conn);
 117         }
 118         return undef;
 119 }
 120
 121 # get rid of a channel object [$obj->del()]
 122 sub del
 123 {
 124         my $self = shift;
 125
 126         $self->{group} = undef;         # belt and braces
 127         delete $channels{$self->{call}};
 128 }
 129
 130 # is it an ak1a cluster ?
 131 sub is_ak1a
 132 {
 133         my $self = shift;
 134         return $self->{'sort'} eq 'A';
 135 }
 136
 137 # is it a user?
 138 sub is_user
 139 {
 140         my $self = shift;
 141         return $self->{'sort'} eq 'U';
 142 }
 143
 144 # is it a connect type
 145 sub is_connect
 146 {
 147         my $self = shift;
 148         return $self->{'sort'} eq 'C';
 149 }
 150
 151 # handle out going messages, immediately without waiting for the select to drop
 152 # this could, in theory, block
 153 sub send_now
 154 {
 155         my $self = shift;
 156         my $conn = $self->{conn};
 157         my $sort = shift;
 158         my $call = $self->{call};
 159
 160         for (@_) {
 161                 chomp;
 162                 $conn->send_now("$sort$call|$_") if $conn;
 163                 dbg('chan', "-> $sort $call $_") if $conn;
 164         }
 165         $self->{t} = time;
 166 }
 167
 168 #
 169 # the normal output routine
 170 #
 171 sub send                                                # this is always later and always data
 172 {
 173         my $self = shift;
 174         my $conn = $self->{conn};
 175         my $call = $self->{call};
 176
 177         for (@_) {
 178                 chomp;
 179                 $conn->send_later("D$call|$_") if $conn;
 180                 dbg('chan', "-> D $call $_") if $conn;
 181         }
 182         $self->{t} = time;
 183 }
 184
 185 # send a file (always later)
 186 sub send_file
 187 {
 188         my ($self, $fn) = @_;
 189         my $call = $self->{call};
 190         my $conn = $self->{conn};
 191         my @buf;
 192
 193         open(F, $fn) or die "can't open $fn for sending file ($!)";
 194         @buf = <F>;
 195         close(F);
 196         $self->send(@buf);
 197 }
 198
 199 # this will implement language independence (in time)
 200 sub msg
 201 {
 202         my $self = shift;
 203         return DXM::msg($self->{lang}, @_);
 204 }
 205
 206 # change the state of the channel - lots of scope for debugging here :-)
 207 sub state
 208 {
 209         my $self = shift;
 210         if (@_) {
 211                 $self->{oldstate} = $self->{state};
 212                 $self->{state} = shift;
 213                 $self->{func} = '' unless defined $self->{func};
 214                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 215         }
 216         return $self->{state};
 217 }
 218
 219 # disconnect this channel
 220 sub disconnect
 221 {
 222         my $self = shift;
 223         my $user = $self->{user};
 224         my $conn = $self->{conn};
 225         my $call = $self->{call};
 226
 227         $self->finish();
 228         $conn->send_now("Z$call|bye") if $conn; # this will cause 'client' to disconnect
 229         $user->close() if defined $user;
 230         $conn->disconnect() if $conn;
 231         $self->del();
 232 }
 233
 234 #
 235 # just close all the socket connections down without any fiddling about, cleaning, being
 236 # nice to other processes and otherwise telling them what is going on.
 237 #
 238 # This is for the benefit of forked processes to prepare for starting new programs, they
 239 # don't want or need all this baggage.
 240 #
 241
 242 sub closeall
 243 {
 244         my $ref;
 245         foreach $ref (values %channels) {
 246                 $ref->{conn}->disconnect() if $ref->{conn};
 247         }
 248 }
 249
 250 # various access routines
 251
 252 #
 253 # return a list of valid elements
 254 #
 255
 256 sub fields
 257 {
 258         return keys(%valid);
 259 }
 260
 261 #
 262 # return a prompt for a field
 263 #
 264
 265 sub field_prompt
 266 {
 267         my ($self, $ele) = @_;
 268         return $valid{$ele};
 269 }
 270
 271 no strict;
 272 sub AUTOLOAD
 273 {
 274         my $self = shift;
 275         my $name = $AUTOLOAD;
 276         return if $name =~ /::DESTROY$/;
 277         $name =~ s/.*:://o;
 278
 279         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 280         @_ ? $self->{$name} = shift : $self->{$name} ;
 281 }
 282
 283 1;
 284 __END__;