perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchann
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO by make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXDebug;
  32 use Filter;
  33
  34 use strict;
  35 use vars qw(%channels %valid);
  36
  37 %channels = ();
  38
  39 %valid = (
  40                   call => '0,Callsign',
  41                   conn => '9,Msg Conn ref',
  42                   user => '9,DXUser ref',
  43                   startt => '0,Start Time,atime',
  44                   t => '9,Time,atime',
  45                   pc50_t => '5,Last PC50 Time,atime',
  46                   priv => '9,Privilege',
  47                   state => '0,Current State',
  48                   oldstate => '5,Last State',
  49                   list => '9,Dep Chan List',
  50                   name => '0,User Name',
  51                   consort => '5,Connection Type',
  52                   'sort' => '5,Type of Channel',
  53                   wwv => '0,Want WWV,yesno',
  54                   wcy => '0,Want WCY,yesno',
  55                   wx => '0,Want WX,yesno',
  56                   talk => '0,Want Talk,yesno',
  57                   ann => '0,Want Announce,yesno',
  58                   here => '0,Here?,yesno',
  59                   confmode => '0,In Conference?,yesno',
  60                   dx => '0,DX Spots,yesno',
  61                   redirect => '0,Redirect messages to',
  62                   lang => '0,Language',
  63                   func => '5,Function',
  64                   loc => '9,Local Vars', # used by func to store local variables in
  65                   beep => '0,Want Beeps,yesno',
  66                   lastread => '5,Last Msg Read',
  67                   outbound => '5,outbound?,yesno',
  68                   remotecmd => '9,doing rcmd,yesno',
  69                   pagelth => '0,Page Length',
  70                   pagedata => '9,Page Data Store',
  71                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  72                   isolate => '5,Isolate network,yesno',
  73                   delayed => '5,Delayed messages,parray',
  74                   annfilter => '5,Announce Filter',
  75                   wwvfilter => '5,WWV Filter',
  76                   wcyfilter => '5,WCY Filter',
  77                   spotfilter => '5,Spot Filter',
  78                   inannfilter => '5,Input Ann Filter',
  79                   inwwvfilter => '5,Input WWV Filter',
  80                   inwcyfilter => '5,Input WCY Filter',
  81                   inspotfilter => '5,Input Spot Filter',
  82                   passwd => '9,Passwd List,parray',
  83                   pingint => '5,Ping Interval ',
  84                   nopings => '5,Ping Obs Count',
  85                   lastping => '5,Ping last sent,atime',
  86                   pingtime => '5,Ping totaltime,parray',
  87                   pingave => '0,Ping ave time',
  88                   logininfo => '9,Login info req,yesno',
  89                   talklist => '0,Talk List,parray',
  90                  );
  91
  92 # object destruction
  93 sub DESTROY
  94 {
  95         my $self = shift;
  96         undef $self->{user};
  97         undef $self->{conn};
  98         undef $self->{loc};
  99         undef $self->{pagedata};
 100         undef $self->{group};
 101         undef $self->{delayed};
 102         undef $self->{annfilter};
 103         undef $self->{wwvfilter};
 104         undef $self->{spotfilter};
 105         undef $self->{inannfilter};
 106         undef $self->{inwwvfilter};
 107         undef $self->{inspotfilter};
 108         undef $self->{passwd};
 109 }
 110
 111 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 112 sub alloc
 113 {
 114         my ($pkg, $call, $conn, $user) = @_;
 115         my $self = {};
 116
 117         die "trying to create a duplicate channel for $call" if $channels{$call};
 118         $self->{call} = $call;
 119         $self->{priv} = 0;
 120         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 121         if (defined $user) {
 122                 $self->{user} = $user;
 123                 $self->{lang} = $user->lang;
 124                 $user->new_group() if !$user->group;
 125                 $self->{group} = $user->group;
 126                 $self->{sort} = $user->sort;
 127         }
 128         $self->{startt} = $self->{t} = time;
 129         $self->{state} = 0;
 130         $self->{oldstate} = 0;
 131         $self->{lang} = $main::lang if !$self->{lang};
 132         $self->{func} = "";
 133
 134         # get the filters
 135         $self->{spotfilter} = Filter::read_in('spots', $call, 0);
 136         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0);
 137         $self->{wcyfilter} = Filter::read_in('wcy', $call, 0);
 138         $self->{annfilter} = Filter::read_in('ann', $call, 0);
 139
 140         bless $self, $pkg;
 141         return $channels{$call} = $self;
 142 }
 143
 144 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 145 sub get
 146 {
 147         my ($pkg, $call) = @_;
 148         return $channels{$call};
 149 }
 150
 151 # obtain all the channel objects
 152 sub get_all
 153 {
 154         my ($pkg) = @_;
 155         return values(%channels);
 156 }
 157
 158 #
 159 # gimme all the ak1a nodes
 160 #
 161 sub get_all_ak1a
 162 {
 163         my @list = DXChannel->get_all();
 164         my $ref;
 165         my @out;
 166         foreach $ref (@list) {
 167                 push @out, $ref if $ref->is_node;
 168         }
 169         return @out;
 170 }
 171
 172 # return a list of all users
 173 sub get_all_users
 174 {
 175         my @list = DXChannel->get_all();
 176         my $ref;
 177         my @out;
 178         foreach $ref (@list) {
 179                 push @out, $ref if $ref->is_user;
 180         }
 181         return @out;
 182 }
 183
 184 # return a list of all user callsigns
 185 sub get_all_user_calls
 186 {
 187         my @list = DXChannel->get_all();
 188         my $ref;
 189         my @out;
 190         foreach $ref (@list) {
 191                 push @out, $ref->call if $ref->is_user;
 192         }
 193         return @out;
 194 }
 195
 196 # obtain a channel object by searching for its connection reference
 197 sub get_by_cnum
 198 {
 199         my ($pkg, $conn) = @_;
 200         my $self;
 201
 202         foreach $self (values(%channels)) {
 203                 return $self if ($self->{conn} == $conn);
 204         }
 205         return undef;
 206 }
 207
 208 # get rid of a channel object [$obj->del()]
 209 sub del
 210 {
 211         my $self = shift;
 212
 213         $self->{group} = undef;         # belt and braces
 214         delete $channels{$self->{call}};
 215 }
 216
 217 # is it a bbs
 218 sub is_bbs
 219 {
 220         my $self = shift;
 221         return $self->{'sort'} eq 'B';
 222 }
 223
 224 sub is_node
 225 {
 226         my $self = shift;
 227         return $self->{'sort'} =~ /[ACRSX]/;
 228 }
 229 # is it an ak1a node ?
 230 sub is_ak1a
 231 {
 232         my $self = shift;
 233         return $self->{'sort'} eq 'A';
 234 }
 235
 236 # is it a user?
 237 sub is_user
 238 {
 239         my $self = shift;
 240         return $self->{'sort'} eq 'U';
 241 }
 242
 243 # is it a clx node
 244 sub is_clx
 245 {
 246         my $self = shift;
 247         return $self->{'sort'} eq 'C';
 248 }
 249
 250 # is it a spider node
 251 sub is_spider
 252 {
 253         my $self = shift;
 254         return $self->{'sort'} eq 'S';
 255 }
 256
 257 # is it a DXNet node
 258 sub is_dxnet
 259 {
 260         my $self = shift;
 261         return $self->{'sort'} eq 'X';
 262 }
 263
 264 # is it a ar-cluster node
 265 sub is_arcluster
 266 {
 267         my $self = shift;
 268         return $self->{'sort'} eq 'R';
 269 }
 270
 271 # for perl 5.004's benefit
 272 sub sort
 273 {
 274         my $self = shift;
 275         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 276 }
 277
 278 # handle out going messages, immediately without waiting for the select to drop
 279 # this could, in theory, block
 280 sub send_now
 281 {
 282         my $self = shift;
 283         my $conn = $self->{conn};
 284         return unless $conn;
 285         my $sort = shift;
 286         my $call = $self->{call};
 287
 288         for (@_) {
 289                 chomp;
 290         my @lines = split /\n/;
 291                 for (@lines) {
 292                         $conn->send_now("$sort$call|$_");
 293                         dbg('chan', "-> $sort $call $_");
 294                 }
 295         }
 296         $self->{t} = time;
 297 }
 298
 299 #
 300 # the normal output routine
 301 #
 302 sub send                                                # this is always later and always data
 303 {
 304         my $self = shift;
 305         my $conn = $self->{conn};
 306         return unless $conn;
 307         my $call = $self->{call};
 308
 309         for (@_) {
 310                 chomp;
 311         my @lines = split /\n/;
 312                 for (@lines) {
 313                         $conn->send_later("D$call|$_");
 314                         dbg('chan', "-> D $call $_");
 315                 }
 316         }
 317         $self->{t} = time;
 318 }
 319
 320 # send a file (always later)
 321 sub send_file
 322 {
 323         my ($self, $fn) = @_;
 324         my $call = $self->{call};
 325         my $conn = $self->{conn};
 326         my @buf;
 327
 328         open(F, $fn) or die "can't open $fn for sending file ($!)";
 329         @buf = <F>;
 330         close(F);
 331         $self->send(@buf);
 332 }
 333
 334 # this will implement language independence (in time)
 335 sub msg
 336 {
 337         my $self = shift;
 338         return DXM::msg($self->{lang}, @_);
 339 }
 340
 341 # stick a broadcast on the delayed queue (but only up to 20 items)
 342 sub delay
 343 {
 344         my $self = shift;
 345         my $s = shift;
 346
 347         $self->{delayed} = [] unless $self->{delayed};
 348         push @{$self->{delayed}}, $s;
 349         if (@{$self->{delayed}} >= 20) {
 350                 shift @{$self->{delayed}};   # lose oldest one
 351         }
 352 }
 353
 354 # change the state of the channel - lots of scope for debugging here :-)
 355 sub state
 356 {
 357         my $self = shift;
 358         if (@_) {
 359                 $self->{oldstate} = $self->{state};
 360                 $self->{state} = shift;
 361                 $self->{func} = '' unless defined $self->{func};
 362                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 363
 364                 # if there is any queued up broadcasts then splurge them out here
 365                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 366                         $self->send (@{$self->{delayed}});
 367                         delete $self->{delayed};
 368                 }
 369         }
 370         return $self->{state};
 371 }
 372
 373 # disconnect this channel
 374 sub disconnect
 375 {
 376         my $self = shift;
 377         my $user = $self->{user};
 378         my $conn = $self->{conn};
 379         my $call = $self->{call};
 380
 381         $self->finish($conn);
 382         $user->close() if defined $user;
 383         $conn->disconnect() if $conn;
 384         $self->del();
 385 }
 386
 387 #
 388 # just close all the socket connections down without any fiddling about, cleaning, being
 389 # nice to other processes and otherwise telling them what is going on.
 390 #
 391 # This is for the benefit of forked processes to prepare for starting new programs, they
 392 # don't want or need all this baggage.
 393 #
 394
 395 sub closeall
 396 {
 397         my $ref;
 398         foreach $ref (values %channels) {
 399                 $ref->{conn}->disconnect() if $ref->{conn};
 400         }
 401 }
 402
 403 #
 404 # Tell all the users that we have come in or out (if they want to know)
 405 #
 406 sub tell_login
 407 {
 408         my ($self, $m) = @_;
 409
 410         # send info to all logged in thingies
 411         my @dxchan = get_all_users();
 412         my $dxchan;
 413         foreach $dxchan (@dxchan) {
 414                 next if $dxchan == $self;
 415                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 416         }
 417 }
 418
 419 # various access routines
 420
 421 #
 422 # return a list of valid elements
 423 #
 424
 425 sub fields
 426 {
 427         return keys(%valid);
 428 }
 429
 430 #
 431 # return a prompt for a field
 432 #
 433
 434 sub field_prompt
 435 {
 436         my ($self, $ele) = @_;
 437         return $valid{$ele};
 438 }
 439
 440 # take a standard input message and decode it into its standard parts
 441 sub decode_input
 442 {
 443         my $dxchan = shift;
 444         my $data = shift;
 445         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 446
 447         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 448
 449         # the above regexp must work
 450         if (!defined $sort || !defined $call || !defined  $line ||
 451                    (ref $dxchan && $call ne $chcall)) {
 452                 $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 453                 dbg('chan', "DUFF Line from $chcall: $data");
 454                 return ();
 455         }
 456
 457         return ($sort, $call, $line);
 458 }
 459
 460 no strict;
 461 sub AUTOLOAD
 462 {
 463         my $self = shift;
 464         my $name = $AUTOLOAD;
 465         return if $name =~ /::DESTROY$/;
 466         $name =~ s/.*:://o;
 467
 468         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 469         @_ ? $self->{$name} = shift : $self->{$name} ;
 470 }
 471
 472 1;
 473 __END__;