perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2016 - Dirk Koopman G1TLH
  23 #
  24 #
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count $maxerrors);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   pc92filter => '5,PC92 Route Filt-out',
  84                   inannfilter => '5,Ann Filt-inp',
  85                   inwwvfilter => '5,WWV Filt-inp',
  86                   inwcyfilter => '5,WCY Filt-inp',
  87                   inspotsfilter => '5,Spot Filt-inp',
  88                   inroutefilter => '5,Route Filt-inp',
  89                   inpc92filter => '5,PC92 Route Filt-inp',
  90                   passwd => '9,Passwd List,yesno',
  91                   pingint => '5,Ping Interval ',
  92                   nopings => '5,Ping Obs Count',
  93                   lastping => '5,Ping last sent,atime',
  94                   pingtime => '5,Ping totaltime,parray',
  95                   pingave => '0,Ping ave time',
  96                   logininfo => '9,Login info req,yesno',
  97                   talklist => '0,Talk List,parray',
  98                   cluster => '5,Cluster data',
  99                   isbasic => '9,Internal Connection',
 100                   errors => '9,Errors',
 101                   route => '9,Route Data',
 102                   dxcc => '0,Country Code',
 103                   itu => '0,ITU Zone',
 104                   cq => '0,CQ Zone',
 105                   enhanced => '5,Enhanced Client,yesno',
 106                   gtk => '5,Using GTK,yesno',
 107                   senddbg => '8,Sending Debug,yesno',
 108                   width => '0,Column Width',
 109                   disconnecting => '9,Disconnecting,yesno',
 110                   ann_talk => '0,Suppress Talk Anns,yesno',
 111                   metric => '1,Route metric',
 112                   badcount => '1,Bad Word Count',
 113                   edit => '7,Edit Function',
 114                   registered => '9,Registered?,yesno',
 115                   prompt => '0,Required Prompt',
 116                   version => '1,Node Version',
 117                   build => '1,Node Build',
 118                   verified => '9,Verified?,yesno',
 119                   newroute => '1,New Style Routing,yesno',
 120                   ve7cc => '0,VE7CC program special,yesno',
 121                   lastmsgpoll => '0,Last Msg Poll,atime',
 122                   inscript => '9,In a script,yesno',
 123                   handle_xml => '9,Handles XML,yesno',
 124                   do_pc9x => '9,Handles PC9x,yesno',
 125                   inqueue => '9,Input Queue,parray',
 126                   next_pc92_update => '9,Next PC92 Update,atime',
 127                   next_pc92_keepalive => '9,Next PC92 KeepAlive,atime',
 128                   hostname => '0,Hostname',
 129                  );
 130
 131 $maxerrors = 20;                                # the maximum number of concurrent errors allowed before disconnection
 132
 133 # object destruction
 134 sub DESTROY
 135 {
 136         my $self = shift;
 137         for (keys %$self) {
 138                 if (ref($self->{$_})) {
 139                         delete $self->{$_};
 140                 }
 141         }
 142         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 143         $count--;
 144 }
 145
 146 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 147 sub alloc
 148 {
 149         my ($pkg, $call, $conn, $user) = @_;
 150         my $self = {};
 151
 152         die "trying to create a duplicate channel for $call" if $channels{$call};
 153         $self->{call} = $call;
 154         $self->{priv} = 0;
 155         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 156         if (defined $user) {
 157                 $self->{user} = $user;
 158                 $self->{lang} = $user->lang;
 159                 $user->new_group unless $user->group;
 160                 $user->new_buddies unless $user->buddies;
 161                 $self->{group} = $user->group;
 162                 $self->{sort} = $user->sort;
 163         }
 164         $self->{startt} = $self->{t} = time;
 165         $self->{state} = 0;
 166         $self->{oldstate} = 0;
 167         $self->{lang} = $main::lang if !$self->{lang};
 168         $self->{func} = "";
 169
 170         # add in all the dxcc, itu, zone info
 171         my @dxcc = Prefix::extract($call);
 172         if (@dxcc > 0) {
 173                 $self->{dxcc} = $dxcc[1]->dxcc;
 174                 $self->{itu} = $dxcc[1]->itu;
 175                 $self->{cq} = $dxcc[1]->cq;
 176         }
 177         $self->{inqueue} = [];
 178
 179         $count++;
 180         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 181         bless $self, $pkg;
 182         return $channels{$call} = $self;
 183 }
 184
 185 # count errors and disconnect if too many
 186 # this has to be here because it can come from rcmd (DXProt) as
 187 # well as DXCommandmode.
 188 sub _error_out
 189 {
 190         my $self = shift;
 191         my $e = shift;
 192         if (++$self->{errors} > $maxerrors) {
 193                 $self->send($self->msg('e26'));
 194                 $self->disconnect;
 195                 return ();
 196         } else {
 197                 return ($self->msg($e));
 198         }
 199 }
 200
 201 # rebless this channel as something else
 202 sub rebless
 203 {
 204         my $self = shift;
 205         my $class = shift;
 206         return $channels{$self->{call}} = bless $self, $class;
 207 }
 208
 209 sub rec
 210 {
 211         my ($self, $msg) = @_;
 212
 213         # queue the message and the channel object for later processing
 214         if (defined $msg) {
 215                 push @{$self->{inqueue}}, $msg;
 216         }
 217         $self->process_one;
 218 }
 219
 220 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 221 sub get
 222 {
 223         my $call = shift;
 224         return $channels{$call};
 225 }
 226
 227 # obtain all the channel objects
 228 sub get_all
 229 {
 230         return values(%channels);
 231 }
 232
 233 #
 234 # gimme all the ak1a nodes
 235 #
 236 sub get_all_nodes
 237 {
 238         my $ref;
 239         my @out;
 240         foreach $ref (values %channels) {
 241                 push @out, $ref if $ref->is_node;
 242         }
 243         return @out;
 244 }
 245
 246 # return a list of node calls
 247 sub get_all_node_calls
 248 {
 249         my $ref;
 250         my @out;
 251         foreach $ref (values %channels) {
 252                 push @out, $ref->{call} if $ref->is_node;
 253         }
 254         return @out;
 255 }
 256
 257 # return a list of all users
 258 sub get_all_users
 259 {
 260         my $ref;
 261         my @out;
 262         foreach $ref (values %channels) {
 263                 push @out, $ref if $ref->is_user;
 264         }
 265         return @out;
 266 }
 267
 268 # return a list of all user callsigns
 269 sub get_all_user_calls
 270 {
 271         my $ref;
 272         my @out;
 273         foreach $ref (values %channels) {
 274                 push @out, $ref->{call} if $ref->is_user;
 275         }
 276         return @out;
 277 }
 278
 279 # obtain a channel object by searching for its connection reference
 280 sub get_by_cnum
 281 {
 282         my ($pkg, $conn) = @_;
 283         my $self;
 284
 285         foreach $self (values(%channels)) {
 286                 return $self if ($self->{conn} == $conn);
 287         }
 288         return undef;
 289 }
 290
 291 # get rid of a channel object [$obj->del()]
 292 sub del
 293 {
 294         my $self = shift;
 295
 296         $self->{group} = undef;         # belt and braces
 297         delete $channels{$self->{call}};
 298 }
 299
 300 # is it a bbs
 301 sub is_bbs
 302 {
 303         return $_[0]->{sort} eq 'B';
 304 }
 305
 306 sub is_node
 307 {
 308         return $_[0]->{sort} =~ /^[ACRSX]$/;
 309 }
 310 # is it an ak1a node ?
 311 sub is_ak1a
 312 {
 313         return $_[0]->{sort} eq 'A';
 314 }
 315
 316 # is it a user?
 317 sub is_user
 318 {
 319         return $_[0]->{sort} =~ /^[UW]$/;
 320 }
 321
 322 # is it a clx node
 323 sub is_clx
 324 {
 325         return $_[0]->{sort} eq 'C';
 326 }
 327
 328 # it is a Web connected user
 329 sub is_web
 330 {
 331         return $_[0]->{sort} eq 'W';
 332 }
 333
 334 # is it a spider node
 335 sub is_spider
 336 {
 337         return $_[0]->{sort} eq 'S';
 338 }
 339
 340 # is it a DXNet node
 341 sub is_dxnet
 342 {
 343         return $_[0]->{sort} eq 'X';
 344 }
 345
 346 # is it a ar-cluster node
 347 sub is_arcluster
 348 {
 349         return $_[0]->{sort} eq 'R';
 350 }
 351
 352 sub is_rbn
 353 {
 354         return $_[0]->{sort} eq 'N';
 355 }
 356
 357 # for perl 5.004's benefit
 358 sub sort
 359 {
 360         my $self = shift;
 361         return @_ ? $self->{sort} = shift : $self->{sort} ;
 362 }
 363
 364 # find out whether we are prepared to believe this callsign on this interface
 365 sub is_believed
 366 {
 367         my $self = shift;
 368         my $call = shift;
 369
 370         return grep $call eq $_, $self->user->believe;
 371 }
 372
 373 # handle out going messages, immediately without waiting for the select to drop
 374 # this could, in theory, block
 375 sub send_now
 376 {
 377         my $self = shift;
 378         my $conn = $self->{conn};
 379         return unless $conn;
 380         my $sort = shift;
 381         my $call = $self->{call};
 382
 383         for (@_) {
 384 #               chomp;
 385         my @lines = split /\n/;
 386                 for (@lines) {
 387                         $conn->send_now("$sort$call|$_");
 388                         # debug log it, but not if it is a log message
 389                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 390                 }
 391         }
 392         $self->{t} = time;
 393 }
 394
 395 #
 396 # send later with letter (more control)
 397 #
 398
 399 sub send_later
 400 {
 401         my $self = shift;
 402         my $conn = $self->{conn};
 403         return unless $conn;
 404         my $sort = shift;
 405         my $call = $self->{call};
 406
 407         for (@_) {
 408 #               chomp;
 409         my @lines = split /\n/;
 410                 for (@lines) {
 411                         $conn->send_later("$sort$call|$_");
 412                         # debug log it, but not if it is a log message
 413                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 414                 }
 415         }
 416         $self->{t} = time;
 417 }
 418
 419 #
 420 # the normal output routine
 421 #
 422 sub send                                                # this is always later and always data
 423 {
 424         my $self = shift;
 425         my $conn = $self->{conn};
 426         return unless $conn;
 427         my $call = $self->{call};
 428
 429         foreach my $l (@_) {
 430                 for (ref $l ? @$l : $l) {
 431                         my @lines = split /\n/;
 432                         for (@lines) {
 433                                 $conn->send_later("D$call|$_");
 434                                 dbg("-> D $call $_") if isdbg('chan');
 435                         }
 436                 }
 437         }
 438         $self->{t} = $main::systime;
 439 }
 440
 441 # send a file (always later)
 442 sub send_file
 443 {
 444         my ($self, $fn) = @_;
 445         my $call = $self->{call};
 446         my $conn = $self->{conn};
 447         my @buf;
 448
 449         open(F, $fn) or die "can't open $fn for sending file ($!)";
 450         @buf = <F>;
 451         close(F);
 452         $self->send(@buf);
 453 }
 454
 455 # this will implement language independence (in time)
 456 sub msg
 457 {
 458         my $self = shift;
 459         return DXM::msg($self->{lang}, @_);
 460 }
 461
 462 # stick a broadcast on the delayed queue (but only up to 20 items)
 463 sub delay
 464 {
 465         my $self = shift;
 466         my $s = shift;
 467
 468         $self->{delayed} = [] unless $self->{delayed};
 469         push @{$self->{delayed}}, $s;
 470         if (@{$self->{delayed}} >= 20) {
 471                 shift @{$self->{delayed}};   # lose oldest one
 472         }
 473 }
 474
 475 # change the state of the channel - lots of scope for debugging here :-)
 476 sub state
 477 {
 478         my $self = shift;
 479         if (@_) {
 480                 $self->{oldstate} = $self->{state};
 481                 $self->{state} = shift;
 482                 $self->{func} = '' unless defined $self->{func};
 483                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 484
 485                 # if there is any queued up broadcasts then splurge them out here
 486                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 487                         $self->send (@{$self->{delayed}});
 488                         delete $self->{delayed};
 489                 }
 490         }
 491         return $self->{state};
 492 }
 493
 494 # disconnect this channel
 495 sub disconnect
 496 {
 497         my $self = shift;
 498         my $user = $self->{user};
 499
 500         $user->close() if defined $user;
 501         $self->{conn}->disconnect if $self->{conn};
 502         $self->del();
 503 }
 504
 505 #
 506 # just close all the socket connections down without any fiddling about, cleaning, being
 507 # nice to other processes and otherwise telling them what is going on.
 508 #
 509 # This is for the benefit of forked processes to prepare for starting new programs, they
 510 # don't want or need all this baggage.
 511 #
 512
 513 sub closeall
 514 {
 515         my $ref;
 516         foreach $ref (values %channels) {
 517                 $ref->{conn}->disconnect() if $ref->{conn};
 518         }
 519 }
 520
 521 #
 522 # Tell all the users that we have come in or out (if they want to know)
 523 #
 524 sub tell_login
 525 {
 526         my ($self, $m, $call) = @_;
 527
 528         $call ||= $self->{call};
 529
 530         # send info to all logged in thingies
 531         my @dxchan = get_all_users();
 532         my $dxchan;
 533         foreach $dxchan (@dxchan) {
 534                 next if $dxchan == $self;
 535                 next if $dxchan->{call} eq $main::mycall;
 536                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 537         }
 538 }
 539
 540 #
 541 # Tell all the users if a buddy is logged or out
 542 #
 543 sub tell_buddies
 544 {
 545         my ($self, $m, $call, $node) = @_;
 546
 547         $call ||= $self->{call};
 548         $call =~ s/-\d+$//;
 549         $m .= 'n' if $node;
 550
 551         # send info to all logged in thingies
 552         my @dxchan = get_all_users();
 553         my $dxchan;
 554         foreach $dxchan (@dxchan) {
 555                 next if $dxchan == $self;
 556                 next if $dxchan->{call} eq $main::mycall;
 557                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 558         }
 559 }
 560
 561 # various access routines
 562
 563 #
 564 # return a list of valid elements
 565 #
 566
 567 sub fields
 568 {
 569         return keys(%valid);
 570 }
 571
 572 #
 573 # return a prompt for a field
 574 #
 575
 576 sub field_prompt
 577 {
 578         my ($self, $ele) = @_;
 579         return $valid{$ele};
 580 }
 581
 582 # take a standard input message and decode it into its standard parts
 583 sub decode_input
 584 {
 585         my $dxchan = shift;
 586         my $data = shift;
 587         my ($sort, $call, $line) = $data =~ /^([A-Z])(#?[A-Z0-9\/\-]{3,25})\|(.*)$/;
 588
 589         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 590
 591         # the above regexp must work
 592         unless (defined $sort && defined $call && defined $line) {
 593 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 594                 dbg("DUFF Line on $chcall: $data");
 595                 return ();
 596         }
 597
 598         if(ref($dxchan) && $call ne $chcall) {
 599                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 600                 return();
 601         }
 602
 603         return ($sort, $call, $line);
 604 }
 605
 606 # broadcast a message to all clusters taking into account isolation
 607 # [except those mentioned after buffer]
 608 sub broadcast_nodes
 609 {
 610         my $s = shift;                          # the line to be rebroadcast
 611         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 612         my @dxchan = get_all_nodes();
 613         my $dxchan;
 614
 615         # send it if it isn't the except list and isn't isolated and still has a hop count
 616         foreach $dxchan (@dxchan) {
 617                 next if grep $dxchan == $_, @except;
 618                 next if $dxchan == $main::me;
 619
 620                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 621
 622                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 623         }
 624 }
 625
 626 # broadcast a message to all clusters ignoring isolation
 627 # [except those mentioned after buffer]
 628 sub broadcast_all_nodes
 629 {
 630         my $s = shift;                          # the line to be rebroadcast
 631         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 632         my @dxchan = get_all_nodes();
 633         my $dxchan;
 634
 635         # send it if it isn't the except list and isn't isolated and still has a hop count
 636         foreach $dxchan (@dxchan) {
 637                 next if grep $dxchan == $_, @except;
 638                 next if $dxchan == $main::me;
 639
 640                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 641                 $dxchan->send($routeit);
 642         }
 643 }
 644
 645 # broadcast to all users
 646 # storing the spot or whatever until it is in a state to receive it
 647 sub broadcast_users
 648 {
 649         my $s = shift;                          # the line to be rebroadcast
 650         my $sort = shift;           # the type of transmission
 651         my $fref = shift;           # a reference to an object to filter on
 652         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 653         my @dxchan = get_all_users();
 654         my $dxchan;
 655         my @out;
 656
 657         foreach $dxchan (@dxchan) {
 658                 next if grep $dxchan == $_, @except;
 659                 push @out, $dxchan;
 660         }
 661         broadcast_list($s, $sort, $fref, @out);
 662 }
 663
 664
 665 # broadcast to a list of users
 666 sub broadcast_list
 667 {
 668         my $s = shift;
 669         my $sort = shift;
 670         my $fref = shift;
 671         my $dxchan;
 672
 673         foreach $dxchan (@_) {
 674                 my $filter = 1;
 675                 next if $dxchan == $main::me;
 676
 677                 if ($sort eq 'dx') {
 678                     next unless $dxchan->{dx};
 679                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 680                         next unless $filter;
 681                 }
 682                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 683                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 684                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 685                 next if $sort eq 'wx' && !$dxchan->{wx};
 686
 687                 $s =~ s/\a//og unless $dxchan->{beep};
 688
 689                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 690                         $dxchan->send($s);
 691                 } else {
 692                         $dxchan->delay($s);
 693                 }
 694         }
 695 }
 696
 697 sub process_one
 698 {
 699         my $self = shift;
 700
 701         while (my $data = shift @{$self->{inqueue}}) {
 702                 my ($sort, $call, $line) = $self->decode_input($data);
 703                 next unless defined $sort;
 704
 705                 # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 706                 dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 707
 708                 # handle A records
 709                 my $user = $self->user;
 710                 if ($sort eq 'I') {
 711                         die "\$user not defined for $call" unless defined $user;
 712
 713                         # normal input
 714                         $self->normal($line);
 715                 } elsif ($sort eq 'G') {
 716                         $self->enhanced($line);
 717                 } elsif ($sort eq 'A' || $sort eq 'O' || $sort eq 'W') {
 718                         $self->start($line, $sort);
 719                 } elsif ($sort eq 'Z') {
 720                         $self->disconnect;
 721                 } elsif ($sort eq 'D') {
 722                         ;                               # ignored (an echo)
 723                 } else {
 724                         dbg atime . " DXChannel::process_one: Unknown command letter ($sort) received from $call\n";
 725                 }
 726         }
 727 }
 728
 729 sub process
 730 {
 731         foreach my $dxchan (values %channels) {
 732                 next if $dxchan->{disconnecting};
 733                 $dxchan->process_one;
 734         }
 735 }
 736
 737 sub handle_xml
 738 {
 739         my $self = shift;
 740         my $r = 0;
 741
 742         if (DXXml::available()) {
 743                 $r = $self->{handle_xml} || 0;
 744         } else {
 745                 delete $self->{handle_xml} if exists $self->{handle_xml};
 746         }
 747         return $r;
 748 }
 749
 750 sub error_handler
 751 {
 752         my $self = shift;
 753         my $error = shift || '';
 754         dbg("$self->{call} ERROR '$error', closing") if isdbg('chan');
 755         $self->{conn}->set_error(undef) if exists $self->{conn};
 756         $self->disconnect(1);
 757 }
 758
 759
 760 #no strict;
 761 sub AUTOLOAD
 762 {
 763         no strict;
 764         my $name = $AUTOLOAD;
 765         return if $name =~ /::DESTROY$/;
 766         $name =~ s/^.*:://o;
 767
 768         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 769
 770         # this clever line of code creates a subroutine which takes over from autoload
 771         # from OO Perl - Conway
 772         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 773         goto &$AUTOLOAD;
 774 }
 775
 776
 777 1;
 778 __END__;