perl/DXCommandmode.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the user facing command mode for a dx cluster
   4 #
   5 # Copyright (c) 1998 Dirk Koopman G1TLH
   6 #
   7 # $Id$
   8 #
   9
  10 package DXCommandmode;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXVars;
  18 use DXDebug;
  19 use DXM;
  20 use DXLog;
  21 use DXLogPrint;
  22 use DXBearing;
  23 use CmdAlias;
  24 use FileHandle;
  25 use Carp;
  26
  27 use strict;
  28 use vars qw(%Cache %cmd_cache $errstr %aliases);
  29
  30 %Cache = ();                                    # cache of dynamically loaded routine's mod times
  31 %cmd_cache = ();                                # cache of short names
  32 $errstr = ();                                   # error string from eval
  33 %aliases = ();                                  # aliases for (parts of) commands
  34
  35 #
  36 # obtain a new connection this is derived from dxchannel
  37 #
  38
  39 sub new
  40 {
  41         my $self = DXChannel::alloc(@_);
  42         $self->{'sort'} = 'U';          # in absence of how to find out what sort of an object I am
  43         return $self;
  44 }
  45
  46 # this is how a a connection starts, you get a hello message and the motd with
  47 # possibly some other messages asking you to set various things up if you are
  48 # new (or nearly new and slacking) user.
  49
  50 sub start
  51 {
  52         my ($self, $line, $sort) = @_;
  53         my $user = $self->{user};
  54         my $call = $self->{call};
  55         my $name = $user->{name};
  56
  57         $self->{name} = $name ? $name : $call;
  58         $self->send($self->msg('l2',$self->{name}));
  59         $self->send_file($main::motd) if (-e $main::motd);
  60         $self->state('prompt');         # a bit of room for further expansion, passwords etc
  61         $self->{priv} = $user->priv;
  62         $self->{lang} = $user->lang;
  63         $self->{pagelth} = 20;
  64         $self->{priv} = 0 if $line =~ /^(ax|te)/; # set the connection priv to 0 - can be upgraded later
  65         $self->{consort} = $line;       # save the connection type
  66
  67         # set some necessary flags on the user if they are connecting
  68         $self->{beep} = $self->{wwv} = $self->{talk} = $self->{ann} = $self->{here} = $self->{dx} = 1;
  69         #  $self->prompt() if $self->{state} =~ /^prompt/o;
  70
  71         # add yourself to the database
  72         my $node = DXNode->get($main::mycall) or die "$main::mycall not allocated in DXNode database";
  73         my $cuser = DXNodeuser->new($self, $node, $call, 0, 1);
  74         $node->dxchan($self) if $call eq $main::myalias; # send all output for mycall to myalias
  75
  76         # issue a pc16 to everybody interested
  77         my $nchan = DXChannel->get($main::mycall);
  78         my @pc16 = DXProt::pc16($nchan, $cuser);
  79         DXProt::broadcast_ak1a(@pc16);
  80         Log('DXCommand', "$call connected");
  81
  82         # send prompts and things
  83         my $info = DXCluster::cluster();
  84         $self->send("Cluster:$info");
  85         $self->send($self->msg('namee1')) if !$user->name;
  86         $self->send($self->msg('qthe1')) if !$user->qth;
  87         $self->send($self->msg('qll')) if !$user->qra || (!$user->lat && !$user->long);
  88         $self->send($self->msg('hnodee1')) if !$user->qth;
  89
  90
  91         $self->send($self->msg('pr', $call));
  92 }
  93
  94 #
  95 # This is the normal command prompt driver
  96 #
  97
  98 sub normal
  99 {
 100         my $self = shift;
 101         my $cmdline = shift;
 102         my @ans;
 103
 104         # remove leading and trailing spaces
 105         $cmdline =~ s/^\s*(.*)\s*$/$1/;
 106
 107         if ($self->{state} eq 'page') {
 108                 my $i = $self->{pagelth};
 109                 my $ref = $self->{pagedata};
 110                 my $tot = @$ref;
 111
 112                 # abort if we get a line starting in with a
 113                 if ($cmdline =~ /^a/io) {
 114                         undef $ref;
 115                         $i = 0;
 116                 }
 117
 118                 # send a tranche of data
 119                 while ($i-- > 0 && @$ref) {
 120                         my $line = shift @$ref;
 121                         $line =~ s/\s+$//o;     # why am having to do this?
 122                         $self->send($line);
 123                 }
 124
 125                 # reset state if none or else chuck out an intermediate prompt
 126                 if ($ref && @$ref) {
 127                         $tot -= $self->{pagelth};
 128                         $self->send($self->msg('page', $tot));
 129                 } else {
 130                         $self->state('prompt');
 131                 }
 132         } else {
 133                 @ans = run_cmd($self, $cmdline);           # if length $cmdline;
 134
 135                 if ($self->{pagelth} && @ans > $self->{pagelth}) {
 136                         my $i;
 137                         for ($i = $self->{pagelth}; $i-- > 0; ) {
 138                                 my $line = shift @ans;
 139                                 $line =~ s/\s+$//o;     # why am having to do this?
 140                                 $self->send($line);
 141                         }
 142                         $self->{pagedata} =  \@ans;
 143                         $self->state('page');
 144                         $self->send($self->msg('page', scalar @ans));
 145                 } else {
 146                         for (@ans) {
 147                                 s/\s+$//o;              # why ?????????
 148                                 $self->send($_);
 149                         }
 150                 }
 151         }
 152
 153         # send a prompt only if we are in a prompt state
 154         $self->prompt() if $self->{state} =~ /^prompt/o;
 155 }
 156
 157 #
 158 # this is the thing that runs the command, it is done like this for the
 159 # benefit of remote command execution
 160 #
 161
 162 sub run_cmd
 163 {
 164         my $self = shift;
 165         my $user = $self->{user};
 166         my $call = $self->{call};
 167         my $cmdline = shift;
 168         my @ans;
 169
 170         if ($self->{func}) {
 171                 my $c = qq{ \@ans = $self->{func}(\$self, \$cmdline) };
 172                 dbg('eval', "stored func cmd = $c\n");
 173                 eval  $c;
 174                 if ($@) {
 175                         return (1, "Syserr: Eval err $errstr on stored func $self->{func}");
 176                 }
 177         } else {
 178
 179                 return () if length $cmdline == 0;
 180
 181                 # strip out //
 182                 $cmdline =~ s|//|/|og;
 183
 184                 # split the command line up into parts, the first part is the command
 185                 my ($cmd, $args) = $cmdline =~ /^([\S\/]+)\s*(.*)/o;
 186
 187                 if ($cmd) {
 188
 189                         my ($path, $fcmd);
 190
 191                         dbg('command', "cmd: $cmd");
 192
 193                         # alias it if possible
 194                         my $acmd = CmdAlias::get_cmd($cmd);
 195                         if ($acmd) {
 196                                 ($cmd, $args) = "$acmd $args" =~ /^([\w\/]+)\s*(.*)/o;
 197                                 dbg('command', "aliased cmd: $cmd $args");
 198                         }
 199
 200                         # first expand out the entry to a command
 201                         ($path, $fcmd) = search($main::localcmd, $cmd, "pl");
 202                         ($path, $fcmd) = search($main::cmd, $cmd, "pl") if !$path || !$fcmd;
 203
 204                         if ($path && $cmd) {
 205                                 dbg('command', "path: $cmd cmd: $fcmd");
 206
 207                                 my $package = find_cmd_name($path, $fcmd);
 208                                 @ans = (0) if !$package ;
 209
 210                                 if ($package) {
 211                                         dbg('command', "package: $package");
 212
 213                                         my $c = qq{ \@ans = $package(\$self, \$args) };
 214                                         dbg('eval', "cluster cmd = $c\n");
 215                                         eval  $c;
 216                                         if ($@) {
 217                                                 @ans = (0, "Syserr: Eval err cached $package\n$@");
 218                                         }
 219                                 }
 220                         } else {
 221                                 dbg('command', "cmd: $cmd not found");
 222                                 @ans = (0);
 223                         }
 224                 }
 225         }
 226
 227         if ($ans[0]) {
 228                 shift @ans;
 229         } else {
 230                 shift @ans;
 231                 if (@ans > 0) {
 232                         unshift @ans, $self->msg('e2');
 233                 } else {
 234                         @ans = $self->msg('e1');
 235                 }
 236         }
 237         return (@ans);
 238 }
 239
 240 #
 241 # This is called from inside the main cluster processing loop and is used
 242 # for despatching commands that are doing some long processing job
 243 #
 244 sub process
 245 {
 246         my $t = time;
 247         my @dxchan = DXChannel->get_all();
 248         my $dxchan;
 249
 250         foreach $dxchan (@dxchan) {
 251                 next if $dxchan->sort ne 'U';
 252
 253                 # send a prompt if no activity out on this channel
 254                 if ($t >= $dxchan->t + $main::user_interval) {
 255                         $dxchan->prompt() if $dxchan->{state} =~ /^prompt/o;
 256                         $dxchan->t($t);
 257                 }
 258         }
 259 }
 260
 261 #
 262 # finish up a user context
 263 #
 264 sub finish
 265 {
 266         my $self = shift;
 267         my $call = $self->call;
 268
 269         # log out text
 270         if (-e "$main::data/logout") {
 271                 open(I, "$main::data/logout") or confess;
 272                 my @in = <I>;
 273                 close(I);
 274                 $self->send_now('D', @in);
 275                 sleep(1);
 276         }
 277
 278         if ($call eq $main::myalias) { # unset the channel if it is us really
 279                 my $node = DXNode->get($main::mycall);
 280                 $node->{dxchan} = 0;
 281         }
 282         my $ref = DXCluster->get_exact($call);
 283
 284         # issue a pc17 to everybody interested
 285         my $nchan = DXChannel->get($main::mycall);
 286         my $pc17 = $nchan->pc17($self);
 287         DXProt::broadcast_ak1a($pc17);
 288
 289         Log('DXCommand', "$call disconnected");
 290         $ref->del() if $ref;
 291 }
 292
 293 #
 294 # short cut to output a prompt
 295 #
 296
 297 sub prompt
 298 {
 299         my $self = shift;
 300         $self->send($self->msg($self->here ? 'pr' : 'pr2', $self->call));
 301 }
 302
 303 # broadcast a message to all users [except those mentioned after buffer]
 304 sub broadcast
 305 {
 306         my $pkg = shift;                        # ignored
 307         my $s = shift;                          # the line to be rebroadcast
 308         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 309         my @list = DXChannel->get_all(); # just in case we are called from some funny object
 310         my ($dxchan, $except);
 311
 312  L: foreach $dxchan (@list) {
 313                 next if !$dxchan->sort eq 'U'; # only interested in user channels
 314                 foreach $except (@except) {
 315                         next L if $except == $dxchan;   # ignore channels in the 'except' list
 316                 }
 317                 $dxchan->send($s);                      # send it
 318         }
 319 }
 320
 321 # gimme all the users
 322 sub get_all
 323 {
 324         my @list = DXChannel->get_all();
 325         my $ref;
 326         my @out;
 327         foreach $ref (@list) {
 328                 push @out, $ref if $ref->sort eq 'U';
 329         }
 330         return @out;
 331 }
 332
 333 #
 334 # search for the command in the cache of short->long form commands
 335 #
 336
 337 sub search
 338 {
 339         my ($path, $short_cmd, $suffix) = @_;
 340         my ($apath, $acmd);
 341
 342         # commands are lower case
 343         $short_cmd = lc $short_cmd;
 344         dbg('command', "command: $path $short_cmd\n");
 345
 346         # do some checking for funny characters
 347         return () if $short_cmd =~ /\/$/;
 348
 349         # return immediately if we have it
 350         ($apath, $acmd) = split ',', $cmd_cache{$short_cmd} if $cmd_cache{$short_cmd};
 351         if ($apath && $acmd) {
 352                 dbg('command', "cached $short_cmd = ($apath, $acmd)\n");
 353                 return ($apath, $acmd);
 354         }
 355
 356         # if not guess
 357         my @parts = split '/', $short_cmd;
 358         my $dirfn;
 359         my $curdir = $path;
 360         my $p;
 361         my $i;
 362         my @lparts;
 363
 364         for ($i = 0; $i < @parts; $i++) {
 365                 my  $p = $parts[$i];
 366                 opendir(D, $curdir) or confess "can't open $curdir $!";
 367                 my @ls = readdir D;
 368                 closedir D;
 369                 my $l;
 370                 foreach $l (sort @ls) {
 371                         next if $l =~ /^\./;
 372                         if ($i < $#parts) {             # we are dealing with directories
 373                                 if ((-d "$curdir/$l") && $p eq substr($l, 0, length $p)) {
 374                                         dbg('command', "got dir: $curdir/$l\n");
 375                                         $dirfn .= "$l/";
 376                                         $curdir .= "/$l";
 377                                         last;
 378                                 }
 379                         } else {                        # we are dealing with commands
 380                                 @lparts = split /\./, $l;
 381                                 next if $lparts[$#lparts] ne $suffix;        # only look for .$suffix files
 382                                 if ($p eq substr($l, 0, length $p)) {
 383                                         pop @lparts; #  remove the suffix
 384                                         $l = join '.', @lparts;
 385                                         #                 chop $dirfn;               # remove trailing /
 386                                         $dirfn = "" unless $dirfn;
 387                                         $cmd_cache{"$short_cmd"} = join(',', ($path, "$dirfn$l")); # cache it
 388                                         dbg('command', "got path: $path cmd: $dirfn$l\n");
 389                                         return ($path, "$dirfn$l");
 390                                 }
 391                         }
 392                 }
 393         }
 394         return ();
 395 }
 396
 397 # clear the command name cache
 398 sub clear_cmd_cache
 399 {
 400         %cmd_cache = ();
 401 }
 402
 403 #
 404 # the persistant execution of things from the command directories
 405 #
 406 #
 407 # This allows perl programs to call functions dynamically
 408 #
 409 # This has been nicked directly from the perlembed pages
 410 #
 411
 412 #require Devel::Symdump;
 413
 414 sub valid_package_name {
 415         my($string) = @_;
 416         $string =~ s/([^A-Za-z0-9\/])/sprintf("_%2x",unpack("C",$1))/eg;
 417
 418         #second pass only for words starting with a digit
 419         $string =~ s|/(\d)|sprintf("/_%2x",unpack("C",$1))|eg;
 420
 421         #Dress it up as a real package name
 422         $string =~ s/\//_/og;
 423         return "Emb_" . $string;
 424 }
 425
 426 #borrowed from Safe.pm
 427 sub delete_package {
 428         my $pkg = shift;
 429         my ($stem, $leaf);
 430
 431         no strict 'refs';
 432         $pkg = "DXCommandmode::$pkg\::"; # expand to full symbol table name
 433         ($stem, $leaf) = $pkg =~ m/(.*::)(\w+::)$/;
 434
 435         if ($stem && $leaf) {
 436                 my $stem_symtab = *{$stem}{HASH};
 437                 delete $stem_symtab->{$leaf};
 438         }
 439 }
 440
 441 # find a cmd reference
 442 # this is really for use in user written stubs
 443 #
 444 # use the result as a symbolic reference:-
 445 #
 446 # no strict 'refs';
 447 # @out = &$r($self, $line);
 448 #
 449 sub find_cmd_ref
 450 {
 451         my $cmd = shift;
 452         my $r;
 453
 454         if ($cmd) {
 455
 456                 # first expand out the entry to a command
 457                 my ($path, $fcmd) = search($main::localcmd, $cmd, "pl");
 458                 ($path, $fcmd) = search($main::cmd, $cmd, "pl") if !$path || !$fcmd;
 459
 460                 # make sure it is loaded
 461                 $r = find_cmd_name($path, $fcmd);
 462         }
 463         return $r;
 464 }
 465
 466 #
 467 # this bit of magic finds a command in the offered directory
 468 sub find_cmd_name {
 469         my $path = shift;
 470         my $cmdname = shift;
 471         my $package = valid_package_name($cmdname);
 472         my $filename = "$path/$cmdname.pl";
 473         my $mtime = -M $filename;
 474
 475         # return if we can't find it
 476         $errstr = undef;
 477         unless (defined $mtime) {
 478                 $errstr = DXM::msg('e1');
 479                 return undef;
 480         }
 481
 482         if(defined $Cache{$package}{mtime} && $Cache{$package}{mtime } <= $mtime) {
 483                 #we have compiled this subroutine already,
 484                 #it has not been updated on disk, nothing left to do
 485                 #print STDERR "already compiled $package->handler\n";
 486                 ;
 487         } else {
 488                 delete_package($package) if defined $Cache{$package}{mtime};
 489
 490                 my $fh = new FileHandle;
 491                 if (!open $fh, $filename) {
 492                         $errstr = "Syserr: can't open '$filename' $!";
 493                         return undef;
 494                 };
 495                 local $/ = undef;
 496                 my $sub = <$fh>;
 497                 close $fh;
 498
 499                 #wrap the code into a subroutine inside our unique package
 500                 my $eval = qq{ sub $package { $sub } };
 501
 502                 if (isdbg('eval')) {
 503                         my @list = split /\n/, $eval;
 504                         my $line;
 505                         for (@list) {
 506                                 dbg('eval', $_, "\n");
 507                         }
 508                 }
 509
 510                 {
 511                         #hide our variables within this block
 512                         my($filename,$mtime,$package,$sub);
 513                         eval $eval;
 514                 }
 515
 516                 if ($@) {
 517                         print "\$\@ = $@";
 518                         $errstr = $@;
 519                         delete_package($package);
 520                 } else {
 521                         #cache it unless we're cleaning out each time
 522                         $Cache{$package}{'mtime'} = $mtime;
 523                 }
 524         }
 525
 526         #print Devel::Symdump->rnew($package)->as_string, $/;
 527         $package = "DXCommandmode::$package" if $package;
 528         $package = undef if $errstr;
 529         return $package;
 530 }
 531
 532 1;
 533 __END__