perl/DXLog.pm

   1 #
   2 # the general purpose logging machine
   3 #
   4 # This module is designed to allow you to log stuff in specific places
   5 # and will rotate logs on a monthly, weekly or daily basis.
   6 #
   7 # The idea is that you give it a prefix which is a directory and then
   8 # the system will log stuff to a directory structure which looks like:-
   9 #
  10 # daily:-
  11 #   spots/1998/<julian day no>[.<optional suffix>]
  12 #
  13 # weekly :-
  14 #   log/1998/<week no>[.<optional suffix>]
  15 #
  16 # monthly
  17 #   wwv/1998/<month>[.<optional suffix>]
  18 #
  19 # Routines are provided to read these files in and to append to them
  20 #
  21 # Copyright (c) - 1998 Dirk Koopman G1TLH
  22 #
  23 # $Id$
  24 #
  25
  26 package DXLog;
  27
  28 require Exporter;
  29 @ISA = qw(Exporter);
  30 @EXPORT = qw(Log Logclose);
  31
  32 use IO::File;
  33 use DXVars;
  34 # use DXDebug ();
  35 use DXUtil;
  36 use Julian;
  37 use Carp;
  38
  39 use strict;
  40 use vars qw($log);
  41
  42 $log = new('log', 'dat', 'm');
  43
  44 # create a log object that contains all the useful info needed
  45 # prefix is the main directory off of the data directory
  46 # sort is 'm' for monthly, 'd' for daily
  47 sub new
  48 {
  49         my ($prefix, $suffix, $sort) = @_;
  50         my $ref = {};
  51         $ref->{prefix} = "$main::data/$prefix";
  52         $ref->{suffix} = $suffix if $suffix;
  53         $ref->{'sort'} = $sort;
  54
  55         # make sure the directory exists
  56         mkdir($ref->{prefix}, 0777) unless -e $ref->{prefix};
  57         return bless $ref;
  58 }
  59
  60 # open the appropriate data file
  61 sub open
  62 {
  63         my ($self, $year, $thing, $mode) = @_;
  64
  65         # if we are writing, check that the directory exists
  66         if (defined $mode) {
  67                 my $dir = "$self->{prefix}/$year";
  68                 mkdir($dir, 0777) if ! -e $dir;
  69         }
  70
  71         $self->{fn} = sprintf "$self->{prefix}/$year/%02d", $thing if $self->{'sort'} eq 'm';
  72         $self->{fn} = sprintf "$self->{prefix}/$year/%03d", $thing if $self->{'sort'} eq 'd';
  73         $self->{fn} .= ".$self->{suffix}" if $self->{suffix};
  74
  75         $mode = 'r' if !$mode;
  76         $self->{mode} = $mode;
  77
  78         my $fh = new IO::File $self->{fn}, $mode, 0666;
  79         return undef if !$fh;
  80         $fh->autoflush(1) if $mode ne 'r'; # make it autoflushing if writable
  81         $self->{fh} = $fh;
  82
  83         $self->{year} = $year;
  84         $self->{thing} = $thing;
  85
  86 #       DXDebug::dbg("dxlog", "opening $self->{fn}\n");
  87
  88         return $self->{fh};
  89 }
  90
  91 # open the previous log file in sequence
  92 sub openprev
  93 {
  94         my $self = shift;
  95         if ($self->{'sort'} eq 'm') {
  96                 ($self->{year}, $self->{thing}) = Julian::subm($self->{year}, $self->{thing}, 1);
  97         } elsif ($self->{'sort'} eq 'd') {
  98                 ($self->{year}, $self->{thing}) = Julian::sub($self->{year}, $self->{thing}, 1);
  99         }
 100         return $self->open($self->{year}, $self->{thing}, @_);
 101 }
 102
 103 # open the next log file in sequence
 104 sub opennext
 105 {
 106         my $self = shift;
 107         if ($self->{'sort'} eq 'm') {
 108                 ($self->{year}, $self->{thing}) = Julian::addm($self->{year}, $self->{thing}, 1);
 109         } elsif ($self->{'sort'} eq 'd') {
 110                 ($self->{year}, $self->{thing}) = Julian::add($self->{year}, $self->{thing}, 1);
 111         }
 112         return $self->open($self->{year}, $self->{thing}, @_);
 113 }
 114
 115 # convert a date into the correct format from a unix date depending on its sort
 116 sub unixtoj
 117 {
 118         my $self = shift;
 119
 120         if ($self->{'sort'} eq 'm') {
 121                 return Julian::unixtojm(shift);
 122         } elsif ($self->{'sort'} eq 'd') {
 123                 return Julian::unixtoj(shift);
 124         }
 125         confess "shouldn't get here";
 126 }
 127
 128 # write (actually append) to a file, opening new files as required
 129 sub write
 130 {
 131         my ($self, $year, $thing, $line) = @_;
 132         if (!$self->{fh} ||
 133                 $self->{mode} ne ">>" ||
 134                 $year != $self->{year} ||
 135                 $thing != $self->{thing}) {
 136                 $self->open($year, $thing, ">>") or confess "can't open $self->{fn} $!";
 137         }
 138
 139         return $self->{fh}->print("$line\n");
 140 }
 141
 142 # write (actually append) using the current date to a file, opening new files as required
 143 sub writenow
 144 {
 145         my ($self, $line) = @_;
 146         my $t = time;
 147         my @date = $self->unixtoj($t);
 148         return $self->write(@date, $line);
 149 }
 150
 151 # write (actually append) using a unix time to a file, opening new files as required
 152 sub writeunix
 153 {
 154         my ($self, $t, $line) = @_;
 155         my @date = $self->unixtoj($t);
 156         return $self->write(@date, $line);
 157 }
 158
 159 # close the log file handle
 160 sub close
 161 {
 162         my $self = shift;
 163         undef $self->{fh};                      # close the filehandle
 164         delete $self->{fh};
 165 }
 166
 167 sub DESTROY
 168 {
 169         my $self = shift;
 170         undef $self->{fh};                      # close the filehandle
 171         delete $self->{fh} if $self->{fh};
 172 }
 173
 174 # log something in the system log
 175 # this routine is exported to any module that declares DXLog
 176 # it takes all its args and joins them together with the unixtime writes them out as one line
 177 # The user is responsible for making sense of this!
 178 sub Log
 179 {
 180         my $t = time;
 181         $log->writeunix($t, join('^', $t, @_) );
 182 }
 183
 184 sub Logclose
 185 {
 186         $log->close();
 187 }
 188 1;