perl/USDB.pm

   1 #
   2 # Package to handle US Callsign -> City, State translations
   3 #
   4 # Copyright (c) 2002 Dirk Koopman G1TLH
   5 #
   6 #
   7
   8 package USDB;
   9
  10 use strict;
  11
  12 use DXVars;
  13 use DB_File;
  14 use File::Copy;
  15 use DXDebug;
  16 #use Compress::Zlib;
  17
  18 use vars qw($VERSION $BRANCH);
  19 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  20 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
  21 $main::build += $VERSION;
  22 $main::branch += $BRANCH;
  23
  24 use vars qw(%db $present $dbfn);
  25
  26 $dbfn = "$main::data/usdb.v1";
  27
  28 sub init
  29 {
  30         end();
  31         if (tie %db, 'DB_File', $dbfn, O_RDONLY, 0664, $DB_BTREE) {
  32                 $present = 1;
  33                 dbg("US Database loaded");
  34         } else {
  35                 dbg("US Database not loaded");
  36         }
  37 }
  38
  39 sub end
  40 {
  41         return unless $present;
  42         untie %db;
  43         undef $present;
  44 }
  45
  46 sub get
  47 {
  48         return () unless $present;
  49         my $ctyn = $db{$_[0]};
  50         my @s = split /\|/, $db{$ctyn} if $ctyn;
  51         return @s;
  52 }
  53
  54 sub getstate
  55 {
  56         return () unless $present;
  57         my @s = get($_[0]);
  58         return @s ? $s[1] : undef;
  59 }
  60
  61 sub getcity
  62 {
  63         return () unless $present;
  64         my @s = get($_[0]);
  65         return @s ? $s[0] : undef;
  66 }
  67
  68 #
  69 # load in / update an existing DB with a standard format (GZIPPED)
  70 # "raw" file.
  71 #
  72 # Note that this removes and overwrites the existing DB file
  73 # You will need to init again after doing this
  74 #
  75
  76 sub load
  77 {
  78         return "Need a filename" unless @_;
  79
  80         # create the new output file
  81         my $a = new DB_File::BTREEINFO;
  82         $a->{psize} = 4096 * 2;
  83         my $s = 0;
  84
  85         # guess a cache size
  86         for (@_) {
  87                 my $ts = -s;
  88                 $s = $ts if $ts > $s;
  89         }
  90         if ($s > 1024 * 1024) {
  91                 $a->{cachesize} = int($s / (1024*1024)) * 3 * 1024 * 1024;
  92         }
  93
  94 #       print "cache size " . $a->{cachesize} . "\n";
  95
  96         my %dbn;
  97         if (-e $dbfn ) {
  98                 copy($dbfn, "$dbfn.new") or return "cannot copy $dbfn -> $dbfn.new $!";
  99         }
 100
 101         tie %dbn, 'DB_File', "$dbfn.new", O_RDWR|O_CREAT, 0664, $a or return "cannot tie $dbfn.new $!";
 102
 103         # now write away all the files
 104         my $count = 0;
 105         for (@_) {
 106                 my $ofn = shift;
 107
 108                 # conditionally handle compressed files (don't cha just lurv live code, this is
 109                 # a rave from the grave and is "in memoriam Flossie" the ICT 1301G I learnt on.
 110                 # {for pedant computer historians a 1301G is an ICT 1301A that has been
 111                 # Galdorised[tm] (for instance had decent IOs and a 24 pre-modify instruction)}
 112                 my $nfn = $ofn;
 113                 if ($nfn =~ /.gz$/i) {
 114                         my $gz;
 115                         eval qq{use Compress::Zlib; \$gz = gzopen(\$ofn, "rb")};
 116                         return "Cannot read compressed files $@" if $@;
 117                         $nfn =~ s/.gz$//i;
 118                         my $of = new IO::File ">$nfn" or return "Cannot write to $nfn $!";
 119                         my ($l, $buf);
 120                         $of->write($buf, $l) while ($l = $gz->gzread($buf));
 121                         $gz->gzclose;
 122                         $of->close;
 123                         $ofn = $nfn;
 124                 }
 125
 126                 my $of = new IO::File "$ofn" or return "Cannot read $ofn $!";
 127
 128                 while (<$of>) {
 129                         my $l = $_;
 130                         $l =~ s/[\r\n]+$//;
 131                         my ($call, $city, $state) = split /\|/, $l;
 132
 133                         # lookup the city
 134                         my $s = "$city|$state";
 135                         my $ctyn = $dbn{$s};
 136                         unless ($ctyn) {
 137                                 my $no = $dbn{'##'} || 1;
 138                                 $ctyn = "#$no";
 139                                 $dbn{$s} = $ctyn;
 140                                 $dbn{$ctyn} = $s;
 141                                 $no++;
 142                                 $dbn{'##'} = "$no";
 143                         }
 144                         $dbn{$call} = $ctyn;
 145                         $count++;
 146                 }
 147                 $of->close;
 148                 unlink $nfn;
 149         }
 150
 151         untie %dbn;
 152         rename "$dbfn.new", $dbfn;
 153         return "$count records";
 154 }
 155
 156 1;