perl/cluster.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # This is the DX cluster 'daemon'. It sits in the middle of its little
   4 # web of client routines sucking and blowing data where it may.
   5 #
   6 # Hence the name of 'spider' (although it may become 'dxspider')
   7 #
   8 # Copyright (c) 1998 Dirk Koopman G1TLH
   9 #
  10 # $Id$
  11 #
  12
  13 require 5.004;
  14
  15 # make sure that modules are searched in the order local then perl
  16 BEGIN {
  17         umask 002;
  18
  19         # root of directory tree for this system
  20         $root = "/spider";
  21         $root = $ENV{'DXSPIDER_ROOT'} if $ENV{'DXSPIDER_ROOT'};
  22
  23         unshift @INC, "$root/perl";     # this IS the right way round!
  24         unshift @INC, "$root/local";
  25
  26         # try to create and lock a lockfile (this isn't atomic but
  27         # should do for now
  28         $lockfn = "$root/perl/cluster.lock";       # lock file name
  29         if (-e $lockfn) {
  30                 open(CLLOCK, "$lockfn") or die "Can't open Lockfile ($lockfn) $!";
  31                 my $pid = <CLLOCK>;
  32                 chomp $pid;
  33                 die "Lockfile ($lockfn) and process $pid exist, another cluster running?" if kill 0, $pid;
  34                 close CLLOCK;
  35         }
  36         open(CLLOCK, ">$lockfn") or die "Can't open Lockfile ($lockfn) $!";
  37         print CLLOCK "$$\n";
  38         close CLLOCK;
  39 }
  40
  41 use Msg;
  42 use DXVars;
  43 use DXDebug;
  44 use DXLog;
  45 use DXLogPrint;
  46 use DXUtil;
  47 use DXChannel;
  48 use DXUser;
  49 use DXM;
  50 use DXCommandmode;
  51 use DXProt;
  52 use DXMsg;
  53 use DXCluster;
  54 use DXCron;
  55 use DXConnect;
  56 use Prefix;
  57 use Bands;
  58 use Geomag;
  59 use CmdAlias;
  60 use Filter;
  61 use Local;
  62 use Fcntl ':flock';
  63
  64 use Carp;
  65
  66 package main;
  67
  68 @inqueue = ();                                  # the main input queue, an array of hashes
  69 $systime = 0;                                   # the time now (in seconds)
  70 $version = "1.28";                              # the version no of the software
  71 $starttime = 0;                 # the starting time of the cluster
  72 $lockfn = "cluster.lock";       # lock file name
  73
  74 # handle disconnections
  75 sub disconnect
  76 {
  77         my $dxchan = shift;
  78         return if !defined $dxchan;
  79         $dxchan->disconnect();
  80 }
  81
  82 # send a message to call on conn and disconnect
  83 sub already_conn
  84 {
  85         my ($conn, $call, $mess) = @_;
  86
  87         dbg('chan', "-> D $call $mess\n");
  88         $conn->send_now("D$call|$mess");
  89         sleep(1);
  90         dbg('chan', "-> Z $call bye\n");
  91         $conn->send_now("Z$call|bye"); # this will cause 'client' to disconnect
  92 }
  93
  94 # handle incoming messages
  95 sub rec
  96 {
  97         my ($conn, $msg, $err) = @_;
  98         my $dxchan = DXChannel->get_by_cnum($conn); # get the dxconnnect object for this message
  99
 100         if (defined $err && $err) {
 101                 disconnect($dxchan) if defined $dxchan;
 102                 return;
 103         }
 104
 105         # set up the basic channel info - this needs a bit more thought - there is duplication here
 106         if (!defined $dxchan) {
 107                 my ($sort, $call, $line) = $msg =~ /^(\w)(\S+)\|(.*)$/;
 108
 109                 # is there one already connected to me ?
 110                 my $user = DXUser->get($call);
 111                 if (DXChannel->get($call)) {
 112                         my $mess = DXM::msg($lang, $user->sort eq 'A' ? 'concluster' : 'conother', $call);
 113                         already_conn($conn, $call, $mess);
 114                         return;
 115                 }
 116
 117                 # is there one already connected elsewhere in the cluster (and not a cluster)
 118                 if ($user) {
 119                         if (($user->sort eq 'A' || $call eq $myalias) && !DXCluster->get_exact($call)) {
 120                                 ;
 121                         } else {
 122                                 if (DXCluster->get($call) || DXChannel->get($call)) {
 123                                         my $mess = DXM::msg($lang, $user->sort eq 'A' ? 'concluster' : 'conother', $call);
 124                                         already_conn($conn, $call, $mess);
 125                                         return;
 126                                 }
 127                         }
 128                         $user->{lang} = $main::lang if !$user->{lang}; # to autoupdate old systems
 129                 } else {
 130                         if (DXCluster->get($call)) {
 131                                 my $mess = DXM::msg($lang, 'conother', $call);
 132                                 already_conn($conn, $call, $mess);
 133                                 return;
 134                         }
 135                         $user = DXUser->new($call);
 136                 }
 137
 138                 # is he locked out ?
 139                 if ($user->lockout) {
 140                         Log('DXCommand', "$call is locked out, disconnected");
 141                         $conn->send_now("Z$call|bye"); # this will cause 'client' to disconnect
 142                         return;
 143                 }
 144
 145                 # create the channel
 146                 $dxchan = DXCommandmode->new($call, $conn, $user) if ($user->sort eq 'U');
 147                 $dxchan = DXProt->new($call, $conn, $user) if ($user->sort eq 'A');
 148                 die "Invalid sort of user on $call = $sort" if !$dxchan;
 149         }
 150
 151         # queue the message and the channel object for later processing
 152         if (defined $msg) {
 153                 my $self = bless {}, "inqueue";
 154                 $self->{dxchan} = $dxchan;
 155                 $self->{data} = $msg;
 156                 push @inqueue, $self;
 157         }
 158 }
 159
 160 sub login
 161 {
 162         return \&rec;
 163 }
 164
 165 # cease running this program, close down all the connections nicely
 166 sub cease
 167 {
 168         my $dxchan;
 169
 170         $SIG{'TERM'} = 'IGNORE';
 171         $SIG{'INT'} = 'IGNORE';
 172
 173         eval {
 174                 Local::finish();   # end local processing
 175         };
 176         dbg('local', "Local::finish error $@") if $@;
 177
 178         foreach $dxchan (DXChannel->get_all()) {
 179                 disconnect($dxchan) unless $dxchan == $DXProt::me;
 180         }
 181         Msg->event_loop(1, 0.05);
 182         Msg->event_loop(1, 0.05);
 183         Msg->event_loop(1, 0.05);
 184         Msg->event_loop(1, 0.05);
 185         Msg->event_loop(1, 0.05);
 186         Msg->event_loop(1, 0.05);
 187         Msg->event_loop(1, 0.05);
 188         Msg->event_loop(1, 0.05);
 189         Msg->event_loop(1, 0.05);
 190         Msg->event_loop(1, 0.05);
 191         Msg->event_loop(1, 0.05);
 192         Msg->event_loop(1, 0.05);
 193         DXUser::finish();
 194         dbg('chan', "DXSpider version $version ended");
 195         Log('cluster', "DXSpider V$version stopped");
 196         unlink $lockfn;
 197         exit(0);
 198 }
 199
 200 # the reaper of children
 201 sub reap
 202 {
 203         $SIG{'CHLD'} = \&reap;
 204         my $cpid = wait;
 205 }
 206
 207 # this is where the input queue is dealt with and things are dispatched off to other parts of
 208 # the cluster
 209 sub process_inqueue
 210 {
 211         my $self = shift @inqueue;
 212         return if !$self;
 213
 214         my $data = $self->{data};
 215         my $dxchan = $self->{dxchan};
 216         my ($sort, $call, $line) = $data =~ /^(\w)(\S+)\|(.*)$/;
 217
 218         # the above regexp must work
 219         return unless ($sort && $call && $line);
 220
 221         # translate any crappy characters into hex characters
 222         if ($line =~ /[\x00-\x06\x08\x0a-\x1f\x7f-\xff]/o) {
 223                 $line =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 224 #               dbg('chan', "<- $sort $call **CRAP**: $line");
 225 #               return;
 226         }
 227
 228         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 229         dbg('chan', "<- $sort $call $line\n") unless $sort eq 'D';
 230
 231         # handle A records
 232         my $user = $dxchan->user;
 233         if ($sort eq 'A' || $sort eq 'O') {
 234                 $dxchan->start($line, $sort);
 235         } elsif ($sort eq 'I') {
 236                 die "\$user not defined for $call" if !defined $user;
 237
 238                 # normal input
 239                 $dxchan->normal($line);
 240
 241                 disconnect($dxchan) if ($dxchan->{state} eq 'bye');
 242         } elsif ($sort eq 'Z') {
 243                 disconnect($dxchan);
 244         } elsif ($sort eq 'D') {
 245                 ;                       # ignored (an echo)
 246         } else {
 247                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 248         }
 249 }
 250
 251 sub uptime
 252 {
 253         my $t = $systime - $starttime;
 254         my $days = int $t / 86400;
 255         $t -= $days * 86400;
 256         my $hours = int $t / 3600;
 257         $t -= $hours * 3600;
 258         my $mins = int $t / 60;
 259         return sprintf "%d %02d:%02d", $days, $hours, $mins;
 260 }
 261 #############################################################
 262 #
 263 # The start of the main line of code
 264 #
 265 #############################################################
 266
 267 $starttime = $systime = time;
 268
 269 # open the debug file, set various FHs to be unbuffered
 270 foreach (@debug) {
 271         dbgadd($_);
 272 }
 273 STDOUT->autoflush(1);
 274
 275 Log('cluster', "DXSpider V$version started");
 276
 277 # banner
 278 print "DXSpider DX Cluster Version $version\nCopyright (c) 1998 Dirk Koopman G1TLH\n";
 279
 280 # load Prefixes
 281 print "loading prefixes ...\n";
 282 Prefix::load();
 283
 284 # load band data
 285 print "loading band data ...\n";
 286 Bands::load();
 287
 288 # initialise User file system
 289 print "loading user file system ...\n";
 290 DXUser->init($userfn, 1);
 291
 292 # start listening for incoming messages/connects
 293 print "starting listener ...\n";
 294 Msg->new_server("$clusteraddr", $clusterport, \&login);
 295
 296 # prime some signals
 297 $SIG{'INT'} = \&cease;
 298 $SIG{'TERM'} = \&cease;
 299 $SIG{'HUP'} = 'IGNORE';
 300 $SIG{'CHLD'} = \&reap;
 301
 302 # read in system messages
 303 DXM->init();
 304
 305 # read in command aliases
 306 CmdAlias->init();
 307
 308 # initialise the Geomagnetic data engine
 309 Geomag->init();
 310
 311 # initial the Spot stuff
 312 Spot->init();
 313
 314 # initialise the protocol engine
 315 print "reading in duplicate spot and WWV info ...\n";
 316 DXProt->init();
 317
 318
 319 # put in a DXCluster node for us here so we can add users and take them away
 320 DXNode->new(0, $mycall, 0, 1, $DXProt::myprot_version);
 321
 322 # read in any existing message headers and clean out old crap
 323 print "reading existing message headers ...\n";
 324 DXMsg->init();
 325 DXMsg::clean_old();
 326
 327 # read in any cron jobs
 328 print "reading cron jobs ...\n";
 329 DXCron->init();
 330
 331 # starting local stuff
 332 print "doing local initialisation ...\n";
 333 eval {
 334         Local::init();
 335 };
 336 dbg('local', "Local::init error $@") if $@;
 337
 338 # print various flags
 339 #print "useful info - \$^D: $^D \$^W: $^W \$^S: $^S \$^P: $^P\n";
 340
 341 # this, such as it is, is the main loop!
 342 print "orft we jolly well go ...\n";
 343 dbg('chan', "DXSpider version $version started...");
 344 for (;;) {
 345         my $timenow;
 346         Msg->event_loop(1, 0.001);
 347         $timenow = time;
 348         process_inqueue();                      # read in lines from the input queue and despatch them
 349
 350         # do timed stuff, ongoing processing happens one a second
 351         if ($timenow != $systime) {
 352                 $systime = $timenow;
 353                 $cldate = &cldate();
 354                 $ztime = &ztime();
 355                 DXCron::process();      # do cron jobs
 356                 DXCommandmode::process(); # process ongoing command mode stuff
 357                 DXProt::process();              # process ongoing ak1a pcxx stuff
 358                 DXConnect::process();
 359                 eval {
 360                         Local::process();       # do any localised processing
 361                 };
 362                 dbg('local', "Local::process error $@") if $@;
 363         }
 364         if ($decease) {
 365                 last if --$decease <= 0;
 366         }
 367 }
 368 cease(0);
 369 exit(0);
 370
 371